blob: c0bd77819d1785f4f36d353f7d0ece216210f58d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
#compdef add-zle-hook-widget
_add-zle-hook-widget_types() {
local -a tmp
autoload -U add-zle-hook-widget
add-zle-hook-widget -h >&/dev/null # sets the zstyle
zstyle -g tmp zle-hook types
compadd "$@" -M 'L:|=zle-' -M 'r:|-=* r:|=*' -- zle-${^tmp}
}
_add-zle-hook-widget_widgets() {
local expl
if (( $+opt_args[-d] )); then
local -a tmp
zstyle -g tmp $line[1] widgets
_wanted widgets expl "installed hook" compadd -- ${tmp#<->:} && return 0
else
_wanted widgets expl widget _widgets -g 'user:*' && return 0
fi
return 1
}
_add-zle-hook-widget() {
local context state state_descr line
typeset -A opt_args
_arguments -s -w -S : \
"(-d -D -U -z -k)-L[output in form of 'zstyle' commands]" \
'(-L -D -U -z -k)-d[remove HOOK from the array]' \
'(-L -d -U -z -k)-D[interpret HOOK as pattern to remove from the array]' \
'(-L -d -D)-U[suppress alias expansion for functions]' \
'(-L -d -D -k)-z[mark function for zsh-style autoloading]' \
'(-L -d -D -z)-k[mark function for ksh-style autoloading]' \
':hook type:_add-zle-hook-widget_types' \
':widget:_add-zle-hook-widget_widgets'
}
_add-zle-hook-widget "$@"
|
