blob: 28563429bcb40b557f202fa6349f1a63414f72fe (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
#compdef service
# *:: for last argument looks more like a hack but it is
# the simplest way known to me to reset $words and keep
# _sub_command happy
# we are interested in init service only
local args actions ctx="${curcontext}argument-1:"
zstyle -T ":completion:${ctx}" tag-order && \
zstyle ":completion:${ctx}" tag-order init
case $OSTYPE in
freebsd<14->.*)
args=( '-E+[set environment variable before executing the rc.d script]:variable:_parameters -g "*export*~*readonly*" -S=' )
;&
freebsd<11->.*)
args+=( '-j+[perform actions in specified jail]:jail:_jails' )
;&
freebsd*|dragonfly*)
actions=(
'(*)-r[show the results of boot time rcorder]'
'(*)-R[restart all enabled local services]'
)
;&
netbsd*)
_arguments -s $args \
'(-e -R)-v[verbose]' \
'*::service argument:_init_d' \
+ '(actions)' $actions \
'(*)-e[show services that are enabled]' \
'(*)-l[list all scripts in /etc/rc.d and the local startup directory]' \
':service name:_services'
;;
*)
_arguments -s \
'(-d --debug)'{-d,--debug}'[turn debugging on]' \
'(- :)'{-h,--help}'[print help information]' \
'(- :)'{-v,--version}'[print version information]' \
'(-)'{-f,--full-restart}'[restart service]' \
'(- :)'{-R,--full-restart-all}'[restart all services]' \
'(- :)'{-s,--status-all}'[print status of all services]' \
':service name:_services' \
'*::service argument: _init_d'
;;
esac
|
