blob: 98ac41e149c79bceceb0ff5dde93ecde35c98e8f (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
#compdef ldd
if _pick_variant gnu='(Free Soft|GNU|GLIBC|Gentoo)' unix --version; then
args=(
'(- *)--version[display version information]'
'(- *)--help[display help information]'
'(-v --verbose)'{-v,--verbose}'[include symbol versioning information]'
'(-d --data-relocs)'{-d,--data-relocs}'[perform data relocations and report missing objects]'
'(-r --function-relocs)'{-r,--function-relocs}'[perform data/function relocations and report missing objects]'
'(-u --unused)'{-u,--unused}'[display any unused objects]'
)
else
case $OSTYPE in
solaris*)
args=(
-s
'(-r)-d[check immediate references]'
'(-d)-r[check immediate and lazy references]'
'-u[display any unused objects]'
'-U[display any unreferenced, or unused dependencies]'
'-e[set specified environment variable]:environment variable:(LD_PRELOAD LD_LIBRARY_PATH LD_RUN_PATH LD_DEBUG LD_DEBUG_OUTPUT LD_NOCONFIG LD_NOAUXFLTR)'
'-f[check for insecure executable]'
'-i[display order of execution of initialization sections]'
'-L[enable lazy loading]'
'-l[force immediate processing of any filters]'
'-s[display search path used]'
'-v[displays all dependency relationships]'
)
;;
freebsd*)
args=(
'-a[show all objects that are needed by each loaded object]'
'*-f+[specify format]:format:((%a\:program\ name %A\:environment\ name %o\:library\ name %p\:path\ to\ library %x\:load\ address))'
)
;;
esac
fi
_arguments $args \
'*: : _alternative
"executables:executable:_files -g \^\*.so\(\-\*\)"
"shared-objects:shared object:_files -g \*.so\(-.\)"'
|
