blob: 778439cf102c267fd68fddee22d9b6b7f888752c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
#compdef cut gcut
typeset -A _cut_args
local -a args
case $LANG in
(de_DE.UTF-8)
_cut_args=(
bytes "nur diese Bytes ausgeben"
characters "nur diese Zeichen ausgeben"
delimiter "Delimiter anstelle von Tabulator als Trenner benutzen"
fields "nur diese Felder und alle Zeilen OHNE Trennzeichen ausgeben"
complement $'das Komplement der Menge der gew\u00e4hlten Bytes, Zeichen oder Felder bilden'
only-delimited "keine Zeilen ausgeben, die keinen Trenner enthalten"
output-delimiter "Zeichenkette als Ausgabetrennzeichen benutzen"
help "diese Hilfe anzeigen und beenden"
version "Versionsinformation anzeigen und beenden"
)
;;
(*)
_cut_args=(
bytes "select only specified bytes"
characters "select only specified characters"
delimiter "use alternate field delimiter"
fields "select only specified fields"
complement "negate the set of selected bytes, characters or fields"
only-delimited "suppress lines with no delimiters"
output-delimiter "use specified string as the output delimiter"
help "display help information"
version "output version information"
)
;;
esac
if _pick_variant gnu="Free Soft" unix --version; then
_arguments \
'(--bytes -b)'{--bytes=,-b+}'['$_cut_args[bytes]']:list' \
'(--characters -c)'{--characters=,-c+}'['$_cut_args[characters]']:list' \
'(--delimiter -d)'{--delimiter=,-d+}'['$_cut_args[delimiter]']:delimiter' \
'(--fields -f)'{--fields=,-f+}'['$_cut_args[fields]']:list' \
'--complement['$_cut_args[complement]']' \
'(--only-delimited -s)'{--only-delimited,-s}'['$_cut_args[only-delimited]']' \
'--output-delimiter=['$_cut_args[output-delimiter]']:delimiter' \
'(- *)--help['$_cut_args[help]']' \
'(- *)--version['$_cut_args[version]']' \
'*:file:_files'
else
case $OSTYPE in
freebsd*|dragonfly*|darwin*) args=( '(-d)-w[use whitespace as the delimiter]' ) ;;
esac
_arguments $args \
"-b[${_cut_args[bytes]}]:list" \
"-c[${_cut_args[characters]}]:list" \
"(-w)-d[${_cut_args[delimiter]}]:delimiter" \
"-f[${_cut_args[fields]}]:list" \
"-n[do not split multi-byte characters]" \
"-s[${_cut_args[only-delimited]}]" \
'*:file:_files'
fi
|
