blob: 9e78af38f23c5a6daba597f60f015193b651e281 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
|
#autoload
## Recommended usage:
# {
# _shadow fname
# function fname {
# # Do your new thing
# }
# # Invoke callers of fname
# } always {
# _unshadow
# }
## Alternate usage:
# {
# _shadow -s suffix fname
# function fname {
# # Do other stuff
# fname@suffix new args for fname
# }
# # Invoke callers of fname
# } always {
# _unshadow
# }
##
# BUGS:
# * `functions -c` acts like `autoload +X`
# * name collisions are possible in alternate usage
# * functions that examine $0 probably misfire
zmodload zsh/parameter # Or what?
# This probably never comes up, but protect ourself from recursive call
# chains that may duplicate the top elements of $funcstack by creating
# a counter of _shadow calls and using it to make shadow names unique.
builtin typeset -gHi .shadow.depth=0
builtin typeset -gHa .shadow.stack
# Create a copy of each fname so that a caller may redefine
_shadow() {
emulate -L zsh
local -A fsfx=( -s ${funcstack[2]}:${functrace[2]}:$((.shadow.depth+1)) )
local fname shadowname
local -a fnames
zparseopts -K -A fsfx -D s:
for fname; do
shadowname=${fname}@${fsfx[-s]}
if (( ${+functions[$shadowname]} ))
then
# Called again with the same -s, just ignore it
continue
elif (( ${+functions[$fname]} ))
then
builtin functions -c -- $fname $shadowname
fnames+=(f@$fname)
elif (( ${+builtins[$fname]} ))
then
eval "function -- ${(q-)shadowname} { builtin ${(q-)fname} \"\$@\" }"
fnames+=(b@$fname)
else
eval "function -- ${(q-)shadowname} { command ${(q-)fname} \"\$@\" }"
fnames+=(c@$fname)
fi
done
[[ -z $REPLY ]] && REPLY=${fsfx[-s]}
builtin set -A .shadow.stack ${fsfx[-s]} $fnames -- ${.shadow.stack}
((.shadow.depth++))
}
# Remove the redefined function and shadowing name
_unshadow() {
emulate -L zsh
local fname shadowname fsfx=${.shadow.stack[1]}
local -a fnames
[[ -n $fsfx ]] || return 1
shift .shadow.stack
while [[ ${.shadow.stack[1]?no shadows} != -- ]]; do
fname=${.shadow.stack[1]#?@}
shadowname=${fname}@${fsfx}
if (( ${+functions[$fname]} )); then
builtin unfunction -- $fname
fi
case ${.shadow.stack[1]} in
(f@*) builtin functions -c -- $shadowname $fname ;&
([bc]@*) builtin unfunction -- $shadowname ;;
esac
shift .shadow.stack
done
[[ -z $REPLY ]] && REPLY=$fsfx
shift .shadow.stack
((.shadow.depth--))
}
# This is tricky. When we call _shadow recursively from autoload,
# there's an extra level of stack in $functrace that will confuse
# the later call to _unshadow. Fool ourself into working correctly.
(( ARGC )) && _shadow -s ${funcstack[2]}:${functrace[2]}:1 "$@"
|
