blob: 3ece0b7ca9ca9a3dd3e8ed71185fe14bb9dcb175 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
#autoload
[[ _matcher_num -gt 1 || $_lastcomp[nmatches] -eq 0 ]] && return 1
local list
zstyle -s ":completion:${curcontext}:" old-list list
# If this is a listing widget and there is already an old list,
# and either the style :oldlist:old-list is `always', or it is not `never'
# and the list is not already shown, then use the existing list for listing
# (even if it was generated by another widget).
# Do this also if there is an old list and it was generated by the
# completer named by the oldlist_list key.
if [[ -n $compstate[old_list] && $list != never &&
$LASTWIDGET != _complete_help && $WIDGET != _complete_help ]]; then
if [[ $WIDGET = *list* && ( $list = always || $list != shown ) ]]; then
compstate[old_list]=keep
return 0
elif [[ $list = *${_lastcomp[completer]}* ]]; then
[[ "$_lastcomp[insert]" = unambig* ]] && compstate[to_end]=single
compstate[old_list]=keep
if [[ -o automenu ]]; then
compstate[insert]=menu
else
compadd -Qs "$SUFFIX" - "$PREFIX"
fi
return 0
fi
fi
# If this is a completion widget, and we have a completion inserted already,
# and the style :oldlist:old-menu is `true', then we cycle through the
# existing list (even if it was generated by another widget).
if [[ -z $compstate[old_insert] && -n $compstate[old_list] &&
( $_lastcomp[nmatches] -ne 0 || $WIDGET != $LASTWIDGET ) &&
$LASTWIDGET != _complete_help && $WIDGET != _complete_help ]]; then
compstate[old_list]=keep
return 0
elif [[ $WIDGET = *complete(|-prefix|-word) ]] &&
zstyle -T ":completion:${curcontext}:" old-menu; then
if [[ -n $compstate[old_insert] ]]; then
compstate[old_list]=keep
if [[ $WIDGET = *reverse* ]]; then
compstate[insert]=$(( compstate[old_insert] - 1 ))
else
compstate[insert]=$(( compstate[old_insert] + 1 ))
fi
else
return 1
fi
return 0
fi
return 1
|
