1 files changed, 29 insertions, 0 deletions
diff --git a/Completion/Zsh/Type/_file_descriptors b/Completion/Zsh/Type/_file_descriptors
new file mode 100644
index 000000000..6d21ed2b6
--- /dev/null
+++ b/Completion/Zsh/Type/_file_descriptors
@@ -0,0 +1,29 @@
+#autoload
+
+local i fds expl list link sep
+
+for i in {0..9}; [[ -e /dev/fd/$i ]] && fds+=( $i )
+
+if zstyle -T ":completion:${curcontext}:" verbose && [[ -e /proc/$$/fd ]]; then
+  zstyle -s ":completion:${curcontext}:" list-separator sep || sep=--
+
+  if zmodload -e zsh/stat; then
+    for i in "${fds[@]}"; do
+      stat +link -A link /proc/$$/fd/$i
+      list+=( "$i $sep ${link[1]}" )
+    done
+  elif (( $+commands[readlink] )); then
+    for i in "${fds[@]}"; list+=( "$i $sep $(readlink /proc/$$/fd/$i)" )
+  else
+    for i in "${fds[@]}"; do
+      list+=( "$i $sep $(ls -l /proc/$$/fd/$i|sed 's/.*-> //' )" )
+    done
+  fi
+
+  if (( $list[(I)* $sep ?*] )); then
+    _wanted file-descriptors expl 'file descriptor' compadd "$@" -d list -a - fds
+    return
+  fi
+fi
+
+_wanted file-descriptors expl 'file descriptor' compadd -a "$@" - fds