rework arm atomic/tp backends to be thumb-compatible and fdpic-ready

three problems are addressed:

- use of pc arithmetic, which was difficult if not impossible to make
  correct in thumb mode on all models, so that relative rather than
  absolute pointers to the backends could be used. this was designed
  back when there was no coherent model for the early stages of the
  dynamic linker before relocations, and is no longer necessary.

- assumption that data (the relative pointers to the backends) can be
  accessed at a constant displacement from the code. this will not be
  possible on future fdpic subarchs (for cortex-m), so move
  responsibility for loading the backend code address to the caller.

- hard-coded arm opcodes using the .word directive. instead, use the
  .arch directive to work around the assembler's refusal to assemble
  instructions not available (or in some cases, available but just
  considered deprecated) in the target isa level. the obscure v6t2
  arch is used for v6 code so as to (1) allow generation of thumb2
  output if -mthumb is active, and (2) avoid warnings/errors for mcr
  barriers that clang would produce if we just set arch to v7-a.

in addition, the __aeabi_read_tp function is moved out of the inner
workings and implemented as an asm wrapper around a C function, so
that asm code does not need to read global data. the asm wrapper
serves to satisfy the ABI calling convention requirements for this
function.

1 files changed, 34 insertions, 41 deletions

diff --git a/src/thread/arm/atomics.s b/src/thread/arm/atomics.s
index 673fc03b..202faa4a 100644
--- a/src/thread/arm/atomics.s
+++ b/src/thread/arm/atomics.s
@@ -1,20 +1,15 @@
 .syntax unified
 .text
 
-.global __a_barrier
-.hidden __a_barrier
-.type __a_barrier,%function
-__a_barrier:
-	ldr ip,1f
-	ldr ip,[pc,ip]
-	add pc,pc,ip
-1:	.word __a_barrier_ptr-1b
 .global __a_barrier_dummy
 .hidden __a_barrier_dummy
+.type __a_barrier_dummy,%function
 __a_barrier_dummy:
 	bx lr
+
 .global __a_barrier_oldkuser
 .hidden __a_barrier_oldkuser
+.type __a_barrier_oldkuser,%function
 __a_barrier_oldkuser:
 	push {r0,r1,r2,r3,ip,lr}
 	mov r1,r0
@@ -24,90 +19,88 @@ __a_barrier_oldkuser:
 	mov pc,ip
 	pop {r0,r1,r2,r3,ip,lr}
 	bx lr
+
 .global __a_barrier_v6
 .hidden __a_barrier_v6
+.type __a_barrier_v6,%function
 __a_barrier_v6:
+	.arch armv6t2
 	mcr p15,0,r0,c7,c10,5
 	bx lr
+
 .global __a_barrier_v7
 .hidden __a_barrier_v7
+.type __a_barrier_v7,%function
 __a_barrier_v7:
-	.word 0xf57ff05b        /* dmb ish */
+	.arch armv7-a
+	dmb ish
 	bx lr
 
-.global __a_cas
-.hidden __a_cas
-.type __a_cas,%function
-__a_cas:
-	ldr ip,1f
-	ldr ip,[pc,ip]
-	add pc,pc,ip
-1:	.word __a_cas_ptr-1b
 .global __a_cas_dummy
 .hidden __a_cas_dummy
+.type __a_cas_dummy,%function
 __a_cas_dummy:
 	mov r3,r0
 	ldr r0,[r2]
 	subs r0,r3,r0
 	streq r1,[r2]
 	bx lr
+
 .global __a_cas_v6
 .hidden __a_cas_v6
+.type __a_cas_v6,%function
 __a_cas_v6:
+	.arch armv6t2
 	mov r3,r0
 	mcr p15,0,r0,c7,c10,5
-1:	.word 0xe1920f9f        /* ldrex r0,[r2] */
+1:	ldrex r0,[r2]
 	subs r0,r3,r0
-	.word 0x01820f91        /* strexeq r0,r1,[r2] */
+	strexeq r0,r1,[r2]
 	teqeq r0,#1
 	beq 1b
 	mcr p15,0,r0,c7,c10,5
 	bx lr
+
 .global __a_cas_v7
 .hidden __a_cas_v7
+.type __a_cas_v7,%function
 __a_cas_v7:
+	.arch armv7-a
 	mov r3,r0
-	.word 0xf57ff05b        /* dmb ish */
-1:	.word 0xe1920f9f        /* ldrex r0,[r2] */
+	dmb ish
+1:	ldrex r0,[r2]
 	subs r0,r3,r0
-	.word 0x01820f91        /* strexeq r0,r1,[r2] */
+	strexeq r0,r1,[r2]
 	teqeq r0,#1
 	beq 1b
-	.word 0xf57ff05b        /* dmb ish */
+	dmb ish
 	bx lr
 
-.global __aeabi_read_tp
-.type __aeabi_read_tp,%function
-__aeabi_read_tp:
-
-.global __a_gettp
-.hidden __a_gettp
-.type __a_gettp,%function
-__a_gettp:
-	ldr r0,1f
-	ldr r0,[pc,r0]
-	add pc,pc,r0
-1:	.word __a_gettp_ptr-1b
-.global __a_gettp_dummy
-.hidden __a_gettp_dummy
-__a_gettp_dummy:
+.global __a_gettp_cp15
+.hidden __a_gettp_cp15
+.type __a_gettp_cp15,%function
+__a_gettp_cp15:
 	mrc p15,0,r0,c13,c0,3
 	bx lr
 
+/* Tag this file with minimum ISA level so as not to affect linking. */
+.arch armv4t
+.eabi_attribute 6,2
+
 .data
 .align 2
 
 .global __a_barrier_ptr
 .hidden __a_barrier_ptr
 __a_barrier_ptr:
-	.word 0
+	.word __a_barrier_dummy
 
 .global __a_cas_ptr
 .hidden __a_cas_ptr
 __a_cas_ptr:
-	.word 0
+	.word __a_cas_dummy
 
 .global __a_gettp_ptr
 .hidden __a_gettp_ptr
 __a_gettp_ptr:
-	.word 0
+	.word __a_gettp_cp15