1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
|
/* Cancellable syscall wrapper. Linux/sh version.
Copyright (C) 2023 Free Software Foundation, Inc.
This file is part of the GNU C Library.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, see
<http://www.gnu.org/licenses/>. */
#include <sysdep.h>
#include <descr-const.h>
/* long int __syscall_cancel_arch (int *cancelhandling,
long int nr,
long int arg1,
long int arg2,
long int arg3,
long int arg4,
long int arg5,
long int arg6) */
ENTRY (__syscall_cancel_arch)
#ifdef SHARED
mov.l r12,@-r15
cfi_def_cfa_offset (4)
cfi_offset (12, -4)
mova L(GT),r0
mov.l L(GT),r12
sts.l pr,@-r15
cfi_def_cfa_offset (8)
cfi_offset (17, -8)
add r0,r12
#else
sts.l pr,@-r15
cfi_def_cfa_offset (4)
cfi_offset (17, -4)
#endif
.globl __syscall_cancel_arch_start
__syscall_cancel_arch_start:
/* if (*cancelhandling & CANCELED_BITMASK)
__syscall_do_cancel() */
mov.l @r4,r0
tst #TCB_CANCELED_BITMASK,r0
bf/s 1f
/* Issue a 6 argument syscall. */
mov r5,r3
mov r6,r4
mov r7,r5
#ifdef SHARED
mov.l @(8,r15),r6
mov.l @(12,r15),r7
mov.l @(16,r15),r0
mov.l @(20,r15),r1
#else
mov.l @(4,r15),r6
mov.l @(8,r15),r7
mov.l @(12,r15),r0
mov.l @(16,r15),r1
#endif
trapa #0x16
.globl __syscall_cancel_arch_end
__syscall_cancel_arch_end:
/* The additional or is a workaround for a hardware issue:
http://documentation.renesas.com/eng/products/mpumcu/tu/tnsh7456ae.pdf
*/
or r0,r0
or r0,r0
or r0,r0
or r0,r0
or r0,r0
lds.l @r15+,pr
cfi_remember_state
cfi_restore (17)
#ifdef SHARED
cfi_def_cfa_offset (4)
rts
mov.l @r15+,r12
cfi_def_cfa_offset (0)
cfi_restore (12)
.align 1
1:
cfi_restore_state
mov.l L(SC),r1
bsrf r1
L(M):
nop
.align 2
L(GT):
.long _GLOBAL_OFFSET_TABLE_
L(SC):
.long __syscall_do_cancel-(L(M)+2)
#else
cfi_def_cfa_offset (0)
rts
nop
.align 1
1:
cfi_restore_state
mov.l 2f,r1
jsr @r1
nop
.align 2
2:
.long __syscall_do_cancel
#endif
END (__syscall_cancel_arch)
|
