scripts/begin-end-check.pl


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

#!/usr/bin/perl

use strict;
use warnings;

# Check __BEGIN_NAMESPACE ... __END_NAMESPACE pairing in an include file.

my $code = 0;
for my $path (@ARGV) {
    my $localcode = 0;
    my @stack;

    open my $in, '<', $path
        or die "open $path failed: $!";

    while (<$in>) {
        if ( /^\s*__BEGIN_(.*)\b/ ) {
            push @stack, $1;
        }
        elsif ( /^\s*__END_(.*)\b/ ) {
            if (@stack) {
                my $tag = pop @stack;
		if ($1 ne $tag) {
                    print "$path:$.: BEGIN $tag paired with END $1\n";
		    $localcode = 1;
		}
            }
            else {
                print "$path:$.: END $1 does not match a begin\n";
		$localcode = 1;
            }
        }
    }

    if (@stack) {
	print "$path: Unmatched begin tags " . join (' ', @stack) ."\n";
	$localcode = 1;
    }

    if ($localcode == 0) {
	print "$path: OK\n";
    } else {
	$code = $localcode;
    }
}

exit $code;