1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
|
/* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <sysdep.h>
#include <shlib-compat.h>
#ifndef UP
# define LOCK lock
#else
# define
#endif
#define SYS_gettimeofday __NR_gettimeofday
#define SYS_futex 202
#define EWOULDBLOCK 11
#define EINVAL 22
#define ETIMEDOUT 110
.text
.globl sem_timedwait
.type sem_timedwait,@function
.align 16
sem_timedwait:
movl (%rdi), %eax
2: testl %eax, %eax
je 1f
leaq -1(%rax), %rdx
LOCK
cmpxchgl %edx, (%rdi)
jne 2b
xorl %eax, %eax
retq
/* Check whether the timeout value is valid. */
1: subq $16, %rsp
movq %rsp, %r10
movq %rdi, %r8
movq %rsi, %r9
/* Check for invalid nanosecond field. */
cmpq $1000000000, 4(%r9)
movl $EINVAL, %eax
jae 6f
7: xorq %rsi, %rsi
movq %rsp, %rdi
movq $SYS_gettimeofday, %rax
syscall
/* Compute relative timeout. */
movq 8(%rsp), %rax
movq $1000, %rdi
mul %rdi /* Milli seconds to nano seconds. */
movq (%r9), %rdi
movq 8(%r9), %rdi
subq (%rsp), %rdi
subq %rax, %rdi
jns 5f
addq $1000000000, %rsi
decq %rdi
5: testq %rdi, %rdi
movl $ETIMEDOUT, %eax
js 6f /* Time is already up. */
movq %rdi, (%rsp) /* Store relative timeout. */
movq %rsi, 8(%rsp)
movq %r8, %rdi
xorq %rsi, %rsi
movq $SYS_futex, %rax
xorl %edx, %edx
syscall
testq %rax, %rax
je 9f
cmpq $-EWOULDBLOCK, %rax
jne 3f
9: movl (%rdi), %eax
8: testl %eax, %eax
je 7b
leaq -1(%rax), %rcx
LOCK
cmpxchgl %ecx, (%rdi)
jne 8b
addq $16, %rsp
xorl %eax, %eax
retq
3: negq %rax
6:
#if USE___THREAD
movq errno@gottpoff(%rip), %rdx
movl %eax, %fs:(%rdx)
#else
movl %eax, %edx
callq __errno_location@plt
movl %edx, (%rax)
#endif
addq $16, %rsp
orl $-1, %eax
retq
.size sem_timedwait,.-sem_timedwait
|
