1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
|
/* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <sysdep.h>
#include <lowlevelrwlock.h>
#define SYS_futex 202
#define FUTEX_WAIT 0
#define FUTEX_WAKE 1
#define EAGAIN 11
#define EDEADLK 35
#ifndef UP
# define LOCK lock
#else
# define LOCK
#endif
.text
.globl __pthread_rwlock_rdlock
.type __pthread_rwlock_rdlock,@function
.align 16
__pthread_rwlock_rdlock:
xorq %r10, %r10
/* Get the lock. */
movl $1, %esi
LOCK
#if MUTEX == 0
xaddl %esi, (%rdi)
#else
xaddl %esi, MUTEX(%rdi)
#endif
testl %esi, %esi
jne 1f
2: movq WRITER(%rdi), %rax
testq %rax, %rax
jne 14f
cmpl $0, WRITERS_QUEUED(%rdi)
je 5f
cmpl $0, FLAGS(%rdi)
je 5f
3: incl READERS_QUEUED(%rdi)
je 4f
movl READERS_WAKEUP(%rdi), %edx
LOCK
#if MUTEX == 0
incl (%rdi)
#else
incl MUTEX(%rdi)
#endif
jne 10f
11: addq $READERS_WAKEUP-MUTEX, %rdi
movq %r10, %rsi /* movl $FUTEX_WAIT, %ecx */
movq $SYS_futex, %rax
syscall
subq $READERS_WAKEUP-MUTEX, %rdi
/* Reget the lock. */
movl $1, %esi
LOCK
#if MUTEX == 0
xaddl %esi, (%rdi)
#else
xaddl %esi, MUTEX(%rdi)
#endif
testl %esi, %esi
jne 12f
13: decl READERS_QUEUED(%rdi)
jmp 2b
5: xorq %rcx, %rcx
incl NR_READERS(%rdi)
je 8f
9: LOCK
#if MUTEX == 0
decl (%rdi)
#else
decl MUTEX(%rdi)
#endif
jne 6f
7:
movq %rcx, %rax
retq
1:
#if MUTEX != 0
addq $MUTEX, %rdi
#endif
call __lll_mutex_lock_wait
#if MUTEX != 0
subq $MUTEX, %rdi
#endif
jmp 2b
14: cmpq %gs:16, %rax
jne 3b
/* Deadlock detected. */
movq $EDEADLK, %rcx
jmp 9b
6:
#if MUTEX != 0
addq $MUTEX, %rdi
#endif
call __lll_mutex_unlock_wake
#if MUTEX != 0
subq $MUTEX, %rdi
#endif
jmp 7b
/* Overflow. */
8: decl NR_READERS(%rdi)
movq $EAGAIN, %rcx
jmp 9b
/* Overflow. */
4: decl READERS_QUEUED(%rdi)
movq $EAGAIN, %rcx
jmp 9b
10:
#if MUTEX != 0
addq $MUTEX, %rdi
#endif
call __lll_mutex_unlock_wake
#if MUTEX != 0
subq $MUTEX, %rdi
#endif
jmp 11b
12:
#if MUTEX == 0
addq $MUTEX, %rdi
#endif
call __lll_mutex_lock_wait
#if MUTEX != 0
subq $MUTEX, %rdi
#endif
jmp 13b
.size __pthread_rwlock_rdlock,.-__pthread_rwlock_rdlock
.globl pthread_rwlock_rdlock
pthread_rwlock_rdlock = __pthread_rwlock_rdlock
.globl __pthread_rwlock_rdlock_internal
__pthread_rwlock_rdlock_internal = __pthread_rwlock_rdlock
|
