1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
/* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <sysdep.h>
#include <shlib-compat.h>
#include <pthread-errnos.h>
#ifndef UP
# define LOCK lock
#else
# define
#endif
#define SYS_futex 240
#define FUTEX_WAKE 1
.text
.globl __new_sem_trywait
.type __new_sem_trywait,@function
.align 16
__new_sem_trywait:
movl 4(%esp), %ecx
movl (%ecx), %eax
2: testl %eax, %eax
jz 1f
leal -1(%eax), %edx
LOCK
cmpxchgl %edx, (%ecx)
jne,pn 2b
xorl %eax, %eax
ret
1:
#ifdef PIC
call __i686.get_pc_thunk.cx
#else
movl $3f, %ecx
3:
#endif
addl $_GLOBAL_OFFSET_TABLE_, %ecx
#if USE___THREAD
movl %gs:0, %edx
subl errno@gottpoff(%ecx), %edx
movl $EAGAIN, (%edx)
#else
call __errno_location@plt
movl $EAGAIN, (%eax)
#endif
orl $-1, %eax
ret
.size __new_sem_trywait,.-__new_sem_trywait
.symver __new_sem_trywait, sem_trywait@@GLIBC_2.1
#if SHLIB_COMPAT(libpthread, GLIBC_2_0, GLIBC_2_1)
.global __old_sem_trywait
__old_sem_trywait = __new_sem_trywait
.symver __old_sem_trywait, sem_trywait@GLIBC_2.0
#endif
#ifdef PIC
.section .gnu.linkonce.t.__i686.get_pc_thunk.cx,"ax",@progbits
.globl __i686.get_pc_thunk.cx
.hidden __i686.get_pc_thunk.cx
.type __i686.get_pc_thunk.cx,@function
__i686.get_pc_thunk.cx:
movl (%esp), %ecx;
ret
.size __i686.get_pc_thunk.cx,.-__i686.get_pc_thunk.cx
#endif
|