1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
|
/* Copyright (C) 2002, 2003 Free Software Foundation, Inc.
This file is part of the GNU C Library.
Contributed by Ulrich Drepper <drepper@redhat.com>, 2002.
The GNU C Library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
The GNU C Library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General Public
License along with the GNU C Library; if not, write to the Free
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
02111-1307 USA. */
#include <sysdep.h>
#include <shlib-compat.h>
#ifdef UP
# define LOCK
#else
# define LOCK lock
#endif
#define SYS_gettimeofday __NR_gettimeofday
#define SYS_futex 240
#define FUTEX_WAIT 0
#define FUTEX_WAKE 1
#define ETIMEDOUT 110
#define cond_lock 0
#define total_seq 4
#define wakeup_seq 12
#define woken_seq 20
.text
.align 16
.type condvar_cleanup, @function
condvar_cleanup:
pushl %ebx
movl 4(%esp), %ebx
#if cond_lock != 0
addl $cond_lock, %ebx
#endif
/* Get internal lock. */
movl $1, %eax
LOCK
#if cond_lock == 0
xaddl %eax, (%ebx)
#else
xaddl %eax, cond_lock(%ebx)
#endif
testl %eax, %eax
je 1f
#if cond_lock == 0
movl %ebx, %ecx
#else
leal cond_lock(%ebx), %ecx
#endif
call __lll_mutex_lock_wait
1: addl $1, wakeup_seq(%ebx)
adcl $0, wakeup_seq+4(%ebx)
addl $1, woken_seq(%ebx)
adcl $0, woken_seq+4(%ebx)
LOCK
decl (%ebx)
je 2f
#if cond_lock == 0
movl %ebx, %eax
#else
leal cond_lock(%ebx), %eax
#endif
call __lll_mutex_unlock_wake
2: popl %ebx
ret
.size condvar_cleanup, .-condvar_cleanup
/* int pthread_cond_wait (pthread_cond_t *cond, pthread_mutex_t *mutex) */
.globl __pthread_cond_wait
.type __pthread_cond_wait, @function
.align 16
__pthread_cond_wait:
pushl %edi
pushl %esi
pushl %ebx
xorl %esi, %esi
movl 16(%esp), %ebx
#if cond_lock != 0
addl $cond_lock, %ebx
#endif
/* Get internal lock. */
movl $1, %eax
LOCK
#if cond_lock == 0
xaddl %eax, (%ebx)
#else
xaddl %eax, cond_lock(%ebx)
#endif
testl %eax, %eax
jne 1f
/* Unlock the mutex. */
2: pushl 20(%esp)
call __pthread_mutex_unlock_internal
addl $1, total_seq(%ebx)
adcl $0, total_seq+4(%ebx)
/* Install cancellation handler. */
#ifdef PIC
call __i686.get_pc_thunk.cx
addl $_GLOBAL_OFFSET_TABLE_, %ecx
leal condvar_cleanup@GOTOFF(%ecx), %eax
#else
leal condvar_cleanup, %eax
#endif
subl $24, %esp
leal 12(%esp), %edx
movl %ebx, 8(%esp)
movl %eax, 4(%esp)
movl %edx, (%esp)
call _GI_pthread_cleanup_push
/* Get and store current wakeup_seq value. */
movl wakeup_seq(%ebx), %edi
movl wakeup_seq+4(%ebx), %edx
movl %edi, 4(%esp)
movl %edx, 8(%esp)
/* Unlock. */
8: LOCK
#if cond_lock == 0
decl (%ebx)
#else
decl cond_lock(%ebx)
#endif
jne 3f
4: call __pthread_enable_asynccancel
movl %eax, (%esp)
movl %esi, %ecx /* movl $FUTEX_WAIT, %ecx */
movl %edi, %edx
addl $wakeup_seq-cond_lock, %ebx
movl $SYS_futex, %eax
ENTER_KERNEL
subl $wakeup_seq-cond_lock, %ebx
call __pthread_disable_asynccancel
/* Lock. */
movl $1, %eax
LOCK
#if cond_lock == 0
xaddl %eax, (%ebx)
#else
xaddl %eax, cond_lock(%ebx)
#endif
testl %eax, %eax
jne 5f
6: movl woken_seq(%ebx), %eax
movl woken_seq+4(%ebx), %ecx
movl wakeup_seq(%ebx), %edi
movl wakeup_seq+4(%ebx), %edx
cmpl 8(%esp), %ecx
ja 7f
jb 8b
cmpl 4(%esp), %eax
jb 8b
7: cmpl %ecx, %edx
ja 9f
jb 8b
cmp %eax, %edi
jna 8b
9: addl $1, woken_seq(%ebx)
adcl $0, woken_seq+4(%ebx)
LOCK
#if cond_lock == 0
decl (%ebx)
#else
decl cond_lock(%ebx)
#endif
jne 10f
/* Remove cancellation handler. */
11: leal 12(%esp), %edx
movl $0, 4(%esp)
movl %edx, (%esp)
call _GI_pthread_cleanup_pop
movl 48(%esp), %eax
movl %eax, (%esp)
call __pthread_mutex_lock_internal
addl $28, %esp
popl %ebx
popl %esi
popl %edi
/* We return the result of the mutex_lock operation. */
ret
/* Initial locking failed. */
1:
#if cond_lock == 0
movl %ebx, %ecx
#else
leal cond_lock(%ebx), %ecx
#endif
call __lll_mutex_lock_wait
jmp 2b
/* Unlock in loop requires waekup. */
3:
#if cond_lock == 0
movl %ebx, %eax
#else
leal cond_lock(%ebx), %eax
#endif
call __lll_mutex_unlock_wake
jmp 4b
/* Locking in loop failed. */
5:
#if cond_lock == 0
movl %ebx, %ecx
#else
leal cond_lock(%ebx), %ecx
#endif
call __lll_mutex_lock_wait
jmp 6b
/* Unlock after loop requires waekup. */
10:
#if cond_lock == 0
movl %ebx, %eax
#else
leal cond_lock(%ebx), %eax
#endif
call __lll_mutex_unlock_wake
jmp 11b
.size __pthread_cond_wait, .-__pthread_cond_wait
versioned_symbol (libpthread, __pthread_cond_wait, pthread_cond_wait,
GLIBC_2_3_2)
/* int pthread_cond_timedwait (pthread_cond_t *cond, pthread_mutex_t *mutex,
const struct timespec *abstime) */
.globl __pthread_cond_timedwait
.type __pthread_cond_timedwait, @function
.align 16
__pthread_cond_timedwait:
pushl %ebp
pushl %edi
pushl %esi
pushl %ebx
movl 20(%esp), %ebx
movl 28(%esp), %ebp
#if cond_lock != 0
addl $cond_lock, %ebx
#endif
/* Get internal lock. */
movl $1, %eax
LOCK
#if cond_lock == 0
xaddl %eax, (%ebx)
#else
xaddl %eax, cond_lock(%ebx)
#endif
testl %eax, %eax
jne 1f
/* Unlock the mutex. */
2: pushl 24(%esp)
call __pthread_mutex_unlock_internal
addl $1, total_seq(%ebx)
adcl $0, total_seq+4(%ebx)
/* Install cancellation handler. */
#ifdef PIC
call __i686.get_pc_thunk.cx
addl $_GLOBAL_OFFSET_TABLE_, %ecx
leal condvar_cleanup@GOTOFF(%ecx), %eax
#else
leal condvar_cleanup, %eax
#endif
subl $32, %esp
leal 16(%esp), %edx
movl %ebx, 8(%esp)
movl %eax, 4(%esp)
movl %edx, (%esp)
call _GI_pthread_cleanup_push
/* Get and store current wakeup_seq value. */
movl wakeup_seq(%ebx), %edi
movl wakeup_seq+4(%ebx), %edx
movl %edi, 12(%esp)
movl %edx, 16(%esp)
/* Unlock. */
8: LOCK
#if cond_lock == 0
decl (%ebx)
#else
decl cond_lock(%ebx)
#endif
jne 3f
4: call __pthread_enable_asynccancel
movl %eax, (%esp)
/* Get the current time. */
movl %ebx, %edx
leal 4(%esp), %ebx
xorl %ecx, %ecx
movl $SYS_gettimeofday, %eax
ENTER_KERNEL
movl %edx, %ebx
/* Compute relative timeout. */
movl 8(%esp), %eax
movl $1000, %edx
mul %edx /* Milli seconds to nano seconds. */
movl (%ebp), %ecx
movl 4(%ebp), %edx
subl 4(%esp), %ecx
subl %eax, %edx
jns 12f
addl $1000000000, %edx
decl %ecx
12: testl %ecx, %ecx
js 13f
/* Store relative timeout. */
movl %ecx, 4(%esp)
movl %edx, 8(%esp)
leal 4(%esp), %esi
xorl %ecx, %ecx /* movl $FUTEX_WAIT, %ecx */
movl %edi, %edx
addl $wakeup_seq-cond_lock, %ebx
movl $SYS_futex, %eax
ENTER_KERNEL
subl $wakeup_seq-cond_lock, %ebx
movl %eax, %esi
call __pthread_disable_asynccancel
/* Lock. */
movl $1, %eax
LOCK
#if cond_lock == 0
xaddl %eax, (%ebx)
#else
xaddl %eax, cond_lock(%ebx)
#endif
testl %eax, %eax
jne 5f
6: movl woken_seq(%ebx), %eax
movl woken_seq+4(%ebx), %ecx
movl wakeup_seq(%ebx), %edi
movl wakeup_seq+4(%ebx), %edx
cmpl 16(%esp), %ecx
ja 7f
jb 15f
cmpl 12(%esp), %eax
jb 15f
7: cmpl %ecx, %edx
ja 9f
jb 15f
cmp %eax, %edi
ja 9f
15: cmpl $-ETIMEDOUT, %esi
jne 8b
13: addl $1, wakeup_seq(%ebx)
adcl $0, wakeup_seq+4(%ebx)
movl $ETIMEDOUT, %esi
jmp 14f
9: xorl %esi, %esi
14: addl $1, woken_seq(%ebx)
adcl $0, woken_seq+4(%ebx)
LOCK
#if cond_lock == 0
decl (%ebx)
#else
decl cond_lock(%ebx)
#endif
jne 10f
/* Remove cancellation handler. */
11: leal 20(%esp), %edx
movl $0, 4(%esp)
movl %edx, (%esp)
call _GI_pthread_cleanup_pop
movl 60(%esp), %ecx
movl %ecx, (%esp)
call __pthread_mutex_lock_internal
addl $36, %esp
movl %esi, %eax
popl %ebx
popl %esi
popl %edi
popl %ebp
/* We return the result of the mutex_lock operation. */
ret
/* Initial locking failed. */
1:
#if cond_lock == 0
movl %ebx, %ecx
#else
leal cond_lock(%ebx), %ecx
#endif
call __lll_mutex_lock_wait
jmp 2b
/* Unlock in loop requires waekup. */
3:
#if cond_lock == 0
movl %ebx, %eax
#else
leal cond_lock(%ebx), %eax
#endif
call __lll_mutex_unlock_wake
jmp 4b
/* Locking in loop failed. */
5:
#if cond_lock == 0
movl %ebx, %ecx
#else
leal cond_lock(%ebx), %ecx
#endif
call __lll_mutex_lock_wait
jmp 6b
/* Unlock after loop requires waekup. */
10:
#if cond_lock == 0
movl %ebx, %eax
#else
leal cond_lock(%ebx), %eax
#endif
call __lll_mutex_unlock_wake
jmp 11b
.size __pthread_cond_timedwait, .-__pthread_cond_timedwait
versioned_symbol (libpthread, __pthread_cond_timedwait, pthread_cond_timedwait,
GLIBC_2_3_2)
/* int pthread_cond_signal (pthread_cond_t *cond) */
.globl __pthread_cond_signal
.type __pthread_cond_signal, @function
.align 16
__pthread_cond_signal:
pushl %esi
pushl %ebx
#if cond_lock != 0
addl $cond_lock, %ebx
#endif
movl 12(%esp), %ebx
/* Get internal lock. */
movl $1, %eax
LOCK
#if cond_lock == 0
xaddl %eax, (%ebx)
#else
xaddl %eax, cond_lock(%ebx)
#endif
testl %eax, %eax
jne 1f
2: movl total_seq+4(%ebx), %eax
movl total_seq(%ebx), %ecx
cmpl wakeup_seq+4(%ebx), %eax
ja 3f
jb 4f
cmpl wakeup_seq(%ebx), %ecx
jbe 4f
/* Bump the wakeup number. */
3: addl $1, wakeup_seq(%ebx)
adcl $0, wakeup_seq+4(%ebx)
/* Wake up one thread. */
addl $wakeup_seq-cond_lock, %ebx
movl $FUTEX_WAKE, %ecx
xorl %esi, %esi
movl $SYS_futex, %eax
movl %ecx, %edx /* movl $1, %edx */
ENTER_KERNEL
subl $wakeup_seq-cond_lock, %ebx
/* Unlock. */
4: LOCK
#if cond_lock == 0
decl (%ebx)
#else
decl cond_lock(%ebx)
#endif
jne 5f
6: xorl %eax, %eax
popl %ebx
popl %esi
ret
/* Initial locking failed. */
1:
#if cond_lock == 0
movl %ebx, %ecx
#else
leal cond_lock(%ebx), %ecx
#endif
call __lll_mutex_lock_wait
jmp 2b
/* Unlock in loop requires waekup. */
5:
#if cond_lock == 0
movl %ebx, %eax
#else
leal cond_lock(%ebx), %eax
#endif
call __lll_mutex_unlock_wake
jmp 6b
.size __pthread_cond_signal, .-__pthread_cond_signal
versioned_symbol (libpthread, __pthread_cond_signal, pthread_cond_signal,
GLIBC_2_3_2)
/* int pthread_cond_broadcast (pthread_cond_t *cond) */
.globl __pthread_cond_broadcast
.type __pthread_cond_broadcast, @function
.align 16
__pthread_cond_broadcast:
pushl %esi
pushl %ebx
movl 12(%esp), %ebx
#if cond_lock != 0
addl $cond_lock, %ebx
#endif
/* Get internal lock. */
movl $1, %eax
LOCK
#if cond_lock == 0
xaddl %eax, (%ebx)
#else
xaddl %eax, cond_lock(%ebx)
#endif
testl %eax, %eax
jne 1f
2: movl total_seq+4(%ebx), %eax
movl total_seq(%ebx), %ecx
cmpl wakeup_seq+4(%ebx), %eax
ja 3f
jb 4f
cmpl wakeup_seq(%ebx), %ecx
jna 4f
/* Case all currently waiting threads to wake up. */
3: movl %ecx, wakeup_seq(%ebx)
movl %eax, wakeup_seq+4(%ebx)
/* Wake up all threads. */
addl $wakeup_seq-cond_lock, %ebx
movl $FUTEX_WAKE, %ecx
xorl %esi, %esi
movl $SYS_futex, %eax
movl $0x7fffffff, %edx
ENTER_KERNEL
subl $wakeup_seq-cond_lock, %ebx
/* Unlock. */
4: LOCK
#if cond_lock == 0
decl (%ebx)
#else
decl cond_lock(%ebx)
#endif
jne 5f
6: xorl %eax, %eax
popl %ebx
popl %esi
ret
/* Initial locking failed. */
1:
#if cond_lock == 0
movl %ebx, %ecx
#else
leal cond_lock(%ebx), %ecx
#endif
call __lll_mutex_lock_wait
jmp 2b
/* Unlock in loop requires waekup. */
5:
#if cond_lock == 0
movl %ebx, %eax
#else
leal cond_lock(%ebx), %eax
#endif
call __lll_mutex_unlock_wake
jmp 6b
.size __pthread_cond_broadcast, .-__pthread_cond_broadcast
versioned_symbol (libpthread, __pthread_cond_broadcast, pthread_cond_broadcast,
GLIBC_2_3_2)
#ifdef PIC
.section .gnu.linkonce.t.__i686.get_pc_thunk.cx,"ax",@progbits
.globl __i686.get_pc_thunk.cx
.hidden __i686.get_pc_thunk.cx
.type __i686.get_pc_thunk.cx,@function
__i686.get_pc_thunk.cx:
movl (%esp), %ecx;
ret
.size __i686.get_pc_thunk.cx,.-__i686.get_pc_thunk.cx
#endif
|
