Update to 960810. cvs/libc-ud-960810 cvs/libc-960811

Sat Aug 10 13:17:27 1996  David Mosberger-Tang  <davidm@azstarnet.com>

	* shadow.h: New file.

	* sysdeps/unix/sysv/linux/netinet/in.h: Move
 	__BEGIN_DECLS/__END_DECLS up so ntohl() et al are bracketed as
 	well.

	* socket/sys/socket.h [__cplusplus]: Use old-style __SOCKADDR_ARG.
	g++ 2.7.2 (and earlier) has no transparent unions support.

Fri Aug  9 18:50:06 1996  David Mosberger-Tang  <davidm@azstarnet.com>

	* sysdeps/unix/sysv/linux/alpha/ioperm.c (_bus_base_sparse): New
	function to determine the base address of sparse bus memory.
	(APECS_*): Rename to CIA_*.
	(APECS_SPARSE_MEM, CIA_SPARSE_MEM): New macros.
	(platform): Add sparse_bus_memory_base member and initialize.
	(sparse_bus_memory_base): New variable.

Tue Aug  6 10:23:18 1996  David Mosberger-Tang  <davidm@azstarnet.com>

	* sysdeps/posix/ttyname_r.c (ttyname_r),
	sysdeps/posix/ttyname.c (ttyname): Return -1/NULL if
	!__isatty(fd) (POSIX.1 says so.)

	* sysdeps/unix/getlogin.c (getlogin): Fix to check fd 0 only.
  	This is not a gross hack, after all---for compatibility,
 	getlogin() really should check fd 0 only and not try to base its
 	operation on the controlling tty.

Wed Jul 17 10:54:20 1996  David Mosberger-Tang  <davidm@azstarnet.com>

	* sysdeps/unix/getlogin.c (getlogin): Add static variable NAME,
 	change utmp_data from static to auto.

Sun Aug 11 02:56:08 1996  Ulrich Drepper  <drepper@cygnus.com>

	* posix/unistd.h [__USE_MISC]: Add prototype for `nice'.
	Reported by David Mosberger-Tang.

1 files changed, 118 insertions, 0 deletions

diff --git a/sysdeps/unix/sysv/linux/alpha/clone.S b/sysdeps/unix/sysv/linux/alpha/clone.S
new file mode 100644
index 0000000000..a1ef324956
--- /dev/null
+++ b/sysdeps/unix/sysv/linux/alpha/clone.S
@@ -0,0 +1,118 @@
+/* Copyright (C) 1996 Free Software Foundation, Inc.
+   Contributed by Richard Henderson (rth@tamu.edu)
+
+The GNU C Library is free software; you can redistribute it and/or
+modify it under the terms of the GNU Library General Public License as
+published by the Free Software Foundation; either version 2 of the
+License, or (at your option) any later version.
+
+The GNU C Library is distributed in the hope that it will be useful,
+but WITHOUT ANY WARRANTY; without even the implied warranty of
+MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
+Library General Public License for more details.
+
+You should have received a copy of the GNU Library General Public
+License along with the GNU C Library; see the file COPYING.LIB.  If
+not, write to the Free Software Foundation, Inc., 675 Mass Ave,
+Cambridge, MA 02139, USA.  */
+
+/* clone() is even more special than fork() as it mucks with stacks
+   and invokes a function in the right context after its all over.  */
+
+#include <sysdep.h>
+#include <errnos.h>
+
+/* int clone(int (*fn)(), void *child_stack, int flags, int nargs, ...) */
+
+        .text
+ENTRY(__clone)
+	lda	sp,-16(sp)
+	.frame	sp,16,$26,0
+	/* Save rest of argument registers for varargs-type work.  */
+	stq	a4,0(sp)
+	stq	a5,8(sp)
+	.prologue 1
+
+	/* Sanity check arguments.  */
+	sextl	a3,a3
+	ldiq	v0,EINVAL
+	beq	a0,$error		/* no NULL function pointers */
+	beq	a1,$error		/* no NULL stack pointers */
+	blt	a3,$error		/* no negative argument counts */
+
+	/* Allocate space on the new stack and copy args over */
+	mov	a3,t0			/* save nargs for thread_start */
+	s8addq	a3,sp,t1
+1:	ldq	t2,-8(t1)
+	subq	t1,8,t1
+	stq	t2,-8(a1)
+	subq	a3,1,a3
+	subq	a1,8,a1
+	bne	a3,1b
+
+	/* Do the system call */
+	mov	a0,pv			/* get fn ptr out of the way */
+	mov	a2,a0
+	ldiq	v0,__NR_clone
+	call_pal PAL_callsys
+
+	bne	a3,$error
+	beq	v0,thread_start
+
+	/* Successful return from the parent */
+	lda	sp,16(sp)
+	ret
+
+	/* Something bad happened -- no child created */
+$error:
+	br	gp,1f
+1:	ldgp	gp,0(gp)
+	lda	sp,16(sp)
+	jmp	zero,__syscall_error
+
+	END(__clone)
+
+/* Load up the arguments to the function.  Put this block of code in
+   its own function so that we can terminate the stack trace with our
+   debug info.
+
+   At this point we have $t0=nargs, $pv=fn, $sp=&arg[0].  */
+
+	.ent thread_start
+thread_start:
+	.frame fp,0,zero,0
+	mov	zero,fp
+	.prologue 0
+
+	/* Calculate address of jump into argument loading code */
+	cmple	t0,6,t2		/* no more than 6 args in registers */
+	cmoveq	t2,6,t0
+	br	v0,1f		/* find address of arg0 */
+1:	lda	v0,$arg0-1b(v0)
+	s4addq	t0,zero,t1
+	subq	v0,t1,v0
+	jmp	(v0)
+
+	/* Load the integer register arguments */
+	ldq	a5,40(sp)
+	ldq	a4,32(sp)
+	ldq	a3,24(sp)
+	ldq	a2,16(sp)
+	ldq	a1,8(sp)
+	ldq	a0,0(sp)
+$arg0:
+
+	/* Adjust stack to remove the arguments we just loaded */
+	s8addq	t0,sp,sp
+
+	/* Call the user's function */
+	jsr	ra,(pv)
+	ldgp	gp,0(ra)
+
+	/* Call _exit rather than doing it inline for breakpoint purposes */
+	mov	v0,a0
+	jsr	ra,_exit
+
+	.end thread_start
+
+weak_alias(__clone, clone)