Update. cvs/libc-ud-970629

1997-06-29 23:43  Ulrich Drepper  <drepper@cygnus.com>

	* config.make.in: Define need-nopic-initfini.
	* configure.in: Write out nopic_initfini.
	* csu/Makefile: Generate no-PIC crt code if need-nopic-initfini
	is defined.

	* sysdeps/i386/fpu/fraiseexcpt.c: Correct FE_INEXACT case.

	* sysdeps/sparc/rem.S: Get trap definition properly.
	* sysdeps/sparc/sdiv.S: Likewise.
	* sysdeps/sparc/udiv.S: Likewise.
	* sysdeps/sparc/urem.S: Likewise.
	* sysdeps/sparc/setjmp.S: Include <sys/trap.h>.
	* sysdeps/sparc/sys/trap.h: New file.
	* sysdeps/unix/sysv/linux/sparc/sys/trap.h: New file.

1997-06-25 10:26  Thorsten Kukuk  <kukuk@uni-paderborn.de>

	* sysdeps/generic/rpc/auth.h: Add xdr_opaque_auth declaration.

1997-06-29 10:34  Fila Kolodny  <fila@ibi.com>

	* sysdeps/mach/hurd/select.c (__select): Change MACH_MSG_SIZE_INTEGER_T
	to MACH_MSG_TYPE_INTEGER_T.

1997-06-29  01:04  Richard Henderson  <richard@gnu.ai.mit.edu>

	Initial sparc64-linux support:
	* configure.in: Recognize sparc64 as being different from sparc.
	* io/ftwtest-sh: Only invoke ld.so if it exists.
	* math/Makefile (LDLIBS-*): Change from libm to math/libm to get
	static tests to link.  Honour $(omit-long-double-fcts) == yes.
	* math/libm-test.c (test_single_exception): The argument to
	fetestexcept is `int' not `fexcept_t'.
	* shlib-versions: Recognize sparc64.
	* signal/signal.h: Add typedef for stack_t.

	* stdio-common/_itoa.c: Defaulting UMUL_TIME==UDIV_TIME is broken.
	Attempt to fix up most of this by cleaning up assumptions below,
	but give up and change the defaults.

	* setjmp/longjmp.c: Moved to ...
	* sysdeps/generic/longjmp.c: ... here.
	* setjmp/sigjmp.c: Moved to ...
	* sysdeps/generic/sigjmp.c: ... here.

	* sysdeps/sparc/bsd-_setjmp.S [PIC]: There wasn't even valid asm here.
	Ought to fix up gas to catch these silly things properly.
	* sysdeps/sparc/bsd-setjmp.S: Likewise.

	* sysdeps/unix/sysv/linux/sparc/errno.c: Remove.
	* sysdeps/unix/sysv/linux/sparc/kernel_sigaction.h: Remove.
	* sysdeps/unix/sysv/linux/sparc/kernel_stat.h: Tell xstat about
	the unused fields.

	* sysdeps/sparc/sparc64/add_n.s: Moved to ...
	* sysdeps/sparc64/add_n.S: ... here.  Fix up %g4 and stack usage.
	* sysdeps/sparc/sparc64/addmul_1.s: Likewise.
	* sysdeps/sparc/sparc64/gmp-mparam.h: Likewise.
	* sysdeps/sparc/sparc64/lshift.s: Likewise.
	* sysdeps/sparc/sparc64/mul_1.s: Likewise.
	* sysdeps/sparc/sparc64/rshift.s: Likewise.
	* sysdeps/sparc/sparc64/sub_n.s: Likewise.
	* sysdeps/sparc/sparc64/submul_1.s: Likewise.

	* sysdeps/sparc64/Implies: New file.
	* sysdeps/sparc64/Makefile: Likewise.
	* sysdeps/sparc64/bits/endian.h: Likewise.
	* sysdeps/sparc64/bsd-_setjmp.S: Likewise.
	* sysdeps/sparc64/bsd-setjmp.S: Likewise.
	* sysdeps/sparc64/dl-machine.h: Likewise.
	* sysdeps/sparc64/elf/Makefile: Likewise.
	* sysdeps/sparc64/elf/crtbegin.S: Likewise.
	* sysdeps/sparc64/elf/crtbeginS.S: Likewise.
	* sysdeps/sparc64/elf/crtend.S: Likewise.
	* sysdeps/sparc64/elf/crtendS.S: Likewise.
	* sysdeps/sparc64/elf/start.S: Likewise.
	* sysdeps/sparc64/fpu_control.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/Makefile: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/__longjmp.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/bits/setjmp.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/bits/types.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/brk.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/clone.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/fork.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/getcontext.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/init-first.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/kernel_stat.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/longjmp.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/pipe.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/profil-counter.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/setcontext.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/setjmp.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/sigjmp.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/syscalls.list: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/sysdep.S: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/sysdep.h: Likewise.
	* sysdeps/unix/sysv/linux/sparc64/ucontext.h: Likewise.

1997-06-28 16:28  H.J. Lu  <hjl@gnu.ai.mit.edu>

	* configure.in: Add -nostartfiles -nostdlib when check for
	--version-script.

1997-06-28 12:03  H.J. Lu  <hjl@gnu.ai.mit.edu>

	* sysdeps/powerpc/bits/endian.h: New file.

1997-06-28 20:52  Ulrich Drepper  <drepper@cygnus.com>

	* sysdeps/unix/sysv/linux/syscalls.list: Add getresgid and
	setresgid.

1 files changed, 93 insertions, 0 deletions

diff --git a/sysdeps/sparc64/rshift.S b/sysdeps/sparc64/rshift.S
new file mode 100644
index 0000000000..e1b3aca112
--- /dev/null
+++ b/sysdeps/sparc64/rshift.S
@@ -0,0 +1,93 @@
+/* SPARC v9 __mpn_rshift --
+
+   Copyright (C) 1996 Free Software Foundation, Inc.
+
+   This file is part of the GNU MP Library.
+
+   The GNU MP Library is free software; you can redistribute it and/or modify
+   it under the terms of the GNU Library General Public License as published by
+   the Free Software Foundation; either version 2 of the License, or (at your
+   option) any later version.
+
+   The GNU MP Library is distributed in the hope that it will be useful, but
+   WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
+   or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Library General Public
+   License for more details.
+
+   You should have received a copy of the GNU Library General Public License
+   along with the GNU MP Library; see the file COPYING.LIB.  If not, write to
+   the Free Software Foundation, Inc., 59 Temple Place - Suite 330, Boston,
+   MA 02111-1307, USA.  */
+
+#include <sysdep.h>
+
+/* INPUT PARAMETERS
+   res_ptr	%i0
+   src_ptr	%i1
+   size		%i2
+   cnt		%i3  */
+
+ENTRY(__mpn_rshift)
+	save	%sp, -128, %sp
+
+	ldx	[%i1],%g2	! load first limb
+	sub	%g0,%i3,%i5	! negate shift count
+	add	%i2,-1,%i2
+	and	%i2,4-1,%l4	! number of limbs in first loop
+	sllx	%g2,%i5,%g1	! compute function result
+	brz,pn	%l4,.L0		! if multiple of 4 limbs, skip first loop
+	mov	%g1,%l1
+
+	sub	%i2,%l4,%i2	! adjust count for main loop
+
+.Loop0:	ldx	[%i1+8],%g3
+	add	%i0,8,%i0
+	add	%i1,8,%i1
+	add	%l4,-1,%l4
+	srlx	%g2,%i3,%i4
+	sllx	%g3,%i5,%g1
+	mov	%g3,%g2
+	or	%i4,%g1,%i4
+	brnz,pt	%l4,.Loop0
+	 stx	%i4,[%i0-8]
+
+.L0:	brz,pn	%i2,.Lend
+	 nop
+
+.Loop:	ldx	[%i1+8],%g3
+	add	%i0,32,%i0
+	add	%i2,-4,%i2
+	srlx	%g2,%i3,%i4
+	sllx	%g3,%i5,%g1
+
+	ldx	[%i1+16],%g2
+	srlx	%g3,%i3,%l4
+	or	%i4,%g1,%i4
+	stx	%i4,[%i0-32]
+	sllx	%g2,%i5,%g1
+
+	ldx	[%i1+24],%g3
+	srlx	%g2,%i3,%i4
+	or	%l4,%g1,%l4
+	stx	%l4,[%i0-24]
+	sllx	%g3,%i5,%g1
+
+	ldx	[%i1+32],%g2
+	srlx	%g3,%i3,%l4
+	or	%i4,%g1,%i4
+	stx	%i4,[%i0-16]
+	sllx	%g2,%i5,%g1
+
+	add	%i1,32,%i1
+	or	%l4,%g1,%l4
+	brnz	%i2,.Loop
+	 stx	%l4,[%i0-8]
+
+.Lend:	srlx	%g2,%i3,%g2
+	stx	%g2,[%i0-0]
+
+	mov	%l1,%i0
+	jmpl	%i7+8,%g0
+	 restore
+
+END(__mpn_rshift)