blob: c6f1e844fba0dce0d428b9ccdb5bce780a68b4b6 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
|
#!/bin/csh -f
#
# pnmindex - build a visual index of a bunch of anymaps
#
# Copyright (C) 1991 by Jef Poskanzer.
#
# Permission to use, copy, modify, and distribute this software and its
# documentation for any purpose and without fee is hereby granted, provided
# that the above copyright notice appear in all copies and that both that
# copyright notice and this permission notice appear in supporting
# documentation. This software is provided "as is" without express or
# implied warranty.
# -title and -quant added by John Heidemann 13-Sep-00.
set size=100 # make the images about this big
set across=6 # show this many images per row
set colors=256 # quantize results to this many colors
set back="-white" # default background color
set doquant=true # quantize or not
set title="" # default title (none)
while ( 1 )
switch ( "$1" )
case -s*:
if ( $#argv < 2 ) goto usage
set size="$2"
shift
shift
breaksw
case -a*:
if ( $#argv < 2 ) goto usage
set across="$2"
shift
shift
breaksw
case -t*:
if ( $#argv < 2 ) goto usage
set title="$2"
shift
shift
breaksw
case -c*:
set colors="$2"
shift
shift
breaksw
case -noq*:
set doquant=false
shift
breaksw
case -q*:
set doquant=true
shift
breaksw
case -b*:
set back="-black"
shift
breaksw
case -w*:
set back="-white"
shift
breaksw
case -*:
goto usage
breaksw
default:
break
breaksw
endsw
end
if ( $#argv == 0 ) then
goto usage
endif
set tmpfile=/tmp/pi.tmp.$$
rm -f $tmpfile
set maxformat=PBM
set rowfiles=()
set imagefiles=()
@ row = 1
@ col = 1
if ( "$title" != "" ) then
set rowfile=/tmp/pi.${row}.$$
rm -f $rowfile
pbmtext "$title" > $rowfile
set rowfiles=( $rowfiles $rowfile )
@ row += 1
endif
foreach i ( $argv )
set description=`pnmfile $i`
if ( $description[4] <= $size && $description[6] <= $size ) then
cat $i > $tmpfile
else
switch ( $description[2] )
case PBM:
pnmscale -quiet -xysize $size $size $i | pgmtopbm > $tmpfile
breaksw
case PGM:
pnmscale -quiet -xysize $size $size $i > $tmpfile
if ( $maxformat == PBM ) then
set maxformat=PGM
endif
breaksw
default:
if ( $doquant == false ) then
pnmscale -quiet -xysize $size $size $i > $tmpfile
else
pnmscale -quiet -xysize $size $size $i | ppmquant -quiet $colors > $tmpfile
endif
set maxformat=PPM
breaksw
endsw
endif
set imagefile=/tmp/pi.${row}.${col}.$$
rm -f $imagefile
if ( "$back" == "-white" ) then
pbmtext "$i" | pnmcat $back -tb $tmpfile - > $imagefile
else
pbmtext "$i" | pnminvert | pnmcat $back -tb $tmpfile - > $imagefile
endif
rm -f $tmpfile
set imagefiles=( $imagefiles $imagefile )
if ( $col >= $across ) then
set rowfile=/tmp/pi.${row}.$$
rm -f $rowfile
if ( $maxformat != PPM || $doquant == false ) then
pnmcat $back -lr -jbottom $imagefiles > $rowfile
else
pnmcat $back -lr -jbottom $imagefiles | ppmquant -quiet $colors > $rowfile
endif
rm -f $imagefiles
set imagefiles=()
set rowfiles=( $rowfiles $rowfile )
@ col = 1
@ row += 1
else
@ col += 1
endif
end
if ( $#imagefiles > 0 ) then
set rowfile=/tmp/pi.${row}.$$
rm -f $rowfile
if ( $maxformat != PPM || $doquant == false ) then
pnmcat $back -lr -jbottom $imagefiles > $rowfile
else
pnmcat $back -lr -jbottom $imagefiles | ppmquant -quiet $colors > $rowfile
endif
rm -f $imagefiles
set rowfiles=( $rowfiles $rowfile )
endif
if ( $#rowfiles == 1 ) then
cat $rowfiles
else
if ( $maxformat != PPM || $doquant == false ) then
pnmcat $back -tb $rowfiles
else
pnmcat $back -tb $rowfiles | ppmquant -quiet $colors
endif
endif
rm -f $rowfiles
exit 0
usage:
echo "usage: $0 [-size N] [-across N] [-colors N] [-black] pnmfile ..."
exit 1
|
