blob: b8145525f505bb0a5892f66480ad063d23a04986 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
# Edit the command line using your usual editor.
# Binding this to '!' in the vi command mode map,
# autoload -Uz edit-command-line
# zle -N edit-command-line
# bindkey -M vicmd '!' edit-command-line
# will give ksh-like behaviour for that key,
# except that it will handle multi-line buffers properly.
() {
exec </dev/tty
# Compute the cursor's position in bytes, not characters.
setopt localoptions nomultibyte noksharrays
(( $+zle_bracketed_paste )) && print -n $zle_bracketed_paste[2]
# Open the editor, placing the cursor at the right place if we know how.
local editor=${${VISUAL:-${EDITOR:-vi}}}
case $editor in
(*vim*)
integer byteoffset=$(( $#PREBUFFER + $#LBUFFER + 1 ))
${=editor} -c "normal! ${byteoffset}go" -- $1;;
(*emacs*)
local lines=( ${(f):-"$PREBUFFER$LBUFFER"} )
${=editor} +${#lines}:$((${#lines[-1]} + 1)) $1;;
(*) ${=editor} $1;;
esac
(( $+zle_bracketed_paste )) && print -n $zle_bracketed_paste[1]
# Replace the buffer with the editor output.
print -Rz - "$(<$1)"
} =(<<<"$PREBUFFER$BUFFER")
zle send-break # Force reload from the buffer stack
|
