blob: 2c7f34b8be63fe0ab408b316a95c765e4dae7a0a (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
|
# Edit the command line using your usual editor.
# Binding this to 'v' in the vi command mode map,
# autoload -Uz edit-command-line
# zle -N edit-command-line
# bindkey -M vicmd v edit-command-line
# will give ksh-like behaviour for that key,
# except that it will handle multi-line buffers properly.
() {
exec </dev/tty
# Compute the cursor's position in bytes, not characters.
setopt localoptions nomultibyte
integer byteoffset=$(( $#PREBUFFER + $#LBUFFER + 1 ))
# Open the editor, placing the cursor at the right place if we know how.
local editor=${${VISUAL:-${EDITOR:-vi}}}
case $editor in
(*vim*) ${=editor} -c "normal! ${byteoffset}go" -- $1;;
(*emacs*) ${=editor} $1 -eval "(goto-char ${byteoffset})";;
(*) ${=editor} $1;;
esac
# Replace the buffer with the editor output.
print -Rz - "$(<$1)"
} =(<<<"$PREBUFFER$BUFFER")
zle send-break # Force reload from the buffer stack
|
