Functions/Math/zmathfunc


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

#autoload

zsh_math_func_min() {
  emulate -L zsh
  local result=$1
  shift
  local arg
  for arg ; do
    (( arg < result ))
    case $? in
      (0) (( result = arg ));;
      (1) ;;
      (*) return $?;;
    esac
  done
  (( result ))
  true # Careful here: `return 0` evaluates an arithmetic expression
}
functions -M min 1 -1 zsh_math_func_min # at least one argument

zsh_math_func_max() {
  emulate -L zsh
  local result=$1
  shift
  local arg
  for arg ; do
    (( arg > result ))
    case $? in
      (0) (( result = arg ));;
      (1) ;;
      (*) return $?;;
    esac
  done
  (( result ))
  true # Careful here: `return 0` evaluates an arithmetic expression
}
functions -M max 1 -1 zsh_math_func_max # at least one argument

zsh_math_func_sum() {
  emulate -L zsh
  local sum
  local arg
  for arg ; do
    (( sum += arg ))
  done
  (( sum ))
  true # Careful here: `return 0` evaluates an arithmetic expression
}
functions -M sum 0 -1 zsh_math_func_sum