Completion/Zsh/Type/_command_names


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

#autoload

# The option `-e' if given as the first argument says that we should
# complete only external commands and executable files. This and a
# `-' as the first argument is then removed from the arguments.

local args defs

defs=(
  'commands:external command:compadd -k commands'
)

if [[ -n "$path[(r).]" ]]; then
  defs=( "$defs[@]"
         'executables:executable file or directory:_path_files -/g \*\(-\*\)'
  )
else
  defs=( "$defs[@]"
         'executables:executable file or directory:_files -P/ -W/ -/g \*\(-\*\)'
  )
fi

if [[ "$1" = -e ]]; then
  shift
else
  [[ "$1" = - ]] && shift

  defs=( "$defs[@]"
    'builtins:builtin command:compadd -k builtins'
    'functions:shell function:compadd -k functions'
    'aliases:alias:compadd -k aliases'
    'reserved-words:reserved word:compadd -k reswords'
    'jobs:: _jobs -t'
    'parameters:: _parameters -g "^*readonly*" -qS= -r "\n\t\- =["'
  )
fi

args=( "$@" )

_alternative -O args "$defs[@]"