blob: 78e929316c829b8a8ffae64eb318bdac36c6528c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
#compdef -value- -array-value-
_value () {
# You can customize completion for different parameters by writing a
# function `_value:<name>', where <name> is the name of the parameter.
# When completing values of elements of associative arrays, we first
# search for a function `_value:<assoc>-<key>' and then for
# `_value:<assoc>', so it's simple to define different functions
# for different keys or one function for a whole association.
if (( $+functions[_value:$compstate[parameter]] )); then
"_value:$compstate[parameter]" "$@"
elif (( $+functions[_value:${compstate[parameter]%%-*}] )); then
"_value:${compstate[parameter]%%-*}" "$@"
elif [[ "$compstate[parameter]" != *-* &&
"${(Pt)${compstate[parameter]}}" = assoc* ]]; then
if (( CURRENT & 1 )); then
_wanted association-keys expl 'association key' \
compadd -k "$compstate[parameter]"
else
compstate[parameter]="${compstate[parameter]}-${words[CURRENT-1]}"
_value "$@"
fi
else
local pats
if { zstyle -a ":completion:${curcontext}:" assign-list pats &&
[[ "$compstate[parameter]" = (${(j:|:)~pats}) ]] } ||
[[ "$PREFIX$SUFFIX" = *:* ]]; then
compset -P '*:'
compset -S ':*'
_default -r '\-\n\t /:' "$@"
else
_default "$@"
fi
fi
}
_value:CPPFLAGS () {
compset -q
if compset -P '-I'; then
_files -/ "$@"
else
_default "$@"
fi
}
_value:LDFLAGS () {
compset -q
if compset -P '-L'; then
_files -/ "$@"
elif compset -P '-R'; then
compset -P '*:'
compset -S ':*'
_files -/ -S/ -r '\n\t\- /:' "$@"
else
_default "$@"
fi
}
_value:DISPLAY() { _x_display "$@" }
_value:TZ() { _time_zone "$@" }
_value "$@"
|
