about summary refs log tree commit diff
path: root/Completion/X/Command/_netscape
blob: 617ec37de4bb532277e58557ec928a58c17d7a0c (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
#compdef netscape

local curcontext="$curcontext" state line ret=1 suf files
typeset -A opt_args

_x_arguments -C \
  '-xrm:resource:_x_resource' \
  '-help[show usage message]' \
  '-version[show the version number and build date]' \
  '-visual[use a specific server visual]:visual:_x_visual -b' \
  '-install[install a private colormap]' \
  '-no-install[use the default colormap]' \
  '-ncols[max no. of colors to allocate for images]:n:' \
  '-mono[force 1-bit-deep image display]' \
  '-iconic[start up iconified]' \
  '-remote[execute a command in an existing Netscape]:remote command:->remote' \
  '-id[id of X window to send remote commands to]:window-id:' \
  '-raise[raise window following remote command]' \
  "-noraise[don't raise window following remote command]" \
  '-nethelp[show nethelp]' \
  -{dont-force-window-stacking,no-about-splash} \
  -{,no-}{,irix-}session-management \
  -{done-save,ignore}-geometry-prefs \
  -{component-bar,composer,edit,messenger,mail,discussions,news} \
  '*:location:->urls' && ret=0

# Handle netscape remote commands
if [[ "$state" = "remote" ]]; then  
  local -a remote_commands
  remote_commands=(openURL openFile saveAs mailto addBookmark)

  compset -P '*\('
  if compset -S '(|\\)\)*'; then
    set - -S "" "$@"
  else
    set - -S"${${QIPREFIX:+)}:-\)}$compstate[quote] " "$@"
  fi
  case $IPREFIX in
    openURL*|addBookmark*) state=urls;;
    openFile*) _files "$@" -W ~;;
    saveAs*) 
      if compset -P "*,"; then
        _wanted types expl 'data type' \
            compadd "$@" -M 'm:{a-zA-Z}={A-Za-z}' HTML Text PostScript && ret=0
      else
        compset -S ",*" || suf=","
        _files -qS "$suf" -W ~ && ret=0
      fi
    ;;
    mailto*)
      compset -P "*,"
      if compset -P '*@'; then
        _wanted hosts expl 'remote host name' _hosts -q -S, && ret=0
      else
        compset -S "@*" || suf="@"
        _wanted users expl 'login name' _users -q -S "$suf" && ret=0
      fi
    ;;
    *)
      compset -S '(|\\)\(*' || suf="${${QIPREFIX:+(}:-\(}"
      _wanted commands expl 'remote commands' \
          compadd -qS "$suf" -M 'm:{a-zA-Z}={A-Za-z}' -a \
                  remote_commands && ret=0
    ;;
  esac
fi

if [[ "$state" = "urls" ]]; then
  _tags files urls
  while _tags; do
    _requested files expl 'file' _files "$@" && files=yes ret=0
    if _requested urls; then
      # Complete netscape urls
      if compset -P about: ; then
	_wanted values expl 'about what' \
            compadd "$@" authors blank cache document fonts global hype \
	    	image-cache license logo memory-cache mozilla plugins && ret=0
      elif compset -P news: ; then
	_newsgroups "$@" && ret=0
      else
	_tags prefixes
	while _tags; do
	  while _next_label prefixes expl 'URL prefix' "$@"; do
            _urls "$expl[@]" && ret=0
	    compset -S '[^:]*'
            compadd -S '' "$expl[@]" about: news: mocha: javascript: && ret=0
	  done
	  (( ret )) || return 0
	done
        [[ -z "$files" ]] && _tags files
      fi
    fi
    (( ret )) || return 0
  done
fi

return ret