blob: 1ad572c1b6fecb0150d17490d95a475b1dd5f70a (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
#compdef mozilla mozilla-firefox mozilla-xremote-client
local curcontext="$curcontext" state line ret=1 suf
typeset -A opt_args
local popts="-installer -CreateProfile -P -ProfileWizard -ProfileManager -SelectProfile"
if [[ $service = *remote* ]]; then
state=remote
else
_x_arguments -C \
'-height[height of startup window]:height' \
'(-)'{-h,-help}'[show usage message]' \
"($popts)-installer[start with 4.x migration window]" \
'-width[width of startup window]:width' \
'(-)'{-v,-version}'[show the version number and build date]' \
"($popts)-CreateProfile:profile" \
"($popts)-P[start with profile]:profile:compadd ~/.mozilla/*/*.slt(\:h\:t)" \
"($popts)-ProfileWizard[start with profile wizard]" \
"($popts)-ProfileManager[start with profile manager]" \
"($popts)-SelectProfile[start with profile selection dialog]" \
'-UILocale:locale' \
'-contentLocale:locale' \
'-remote[execute a command in an existing Mozilla]:remote command:->remote' \
'-splash[enable splash screen]' \
'-chat[start with IRC client]' \
'-news[start with news]' \
'-jsconsole[start with JavaScript Console]' \
'-venkman[start with JavaScript debugger]' \
'-terminal[start with command line terminal]' \
'-edit[start with editor]:url:_urls' \
'-chrome[load the specified chrome]:url:_urls' \
'-mail[start with mail]' \
'-compose[start with messenger compose]:url:_urls' \
'*:location:->urls' && ret=0
fi
[[ "$state" = "urls" ]] &&
_files "$@" && return 0
# Handle mozilla remote commands
if [[ "$state" = "remote" ]]; then
local -a remote_commands
remote_commands=(openURL openFile saveAs mailto addBookmark ping)
compset -P '*\('
if compset -S '(|\\)\)*'; then
set - -S "" "$@"
else
set - -S"${${QIPREFIX:+)}:-\)}$compstate[quote] " "$@"
fi
case $IPREFIX in
openURL*)
if compset -P "*,"; then
_wanted option expl 'option' compadd "$@" new-tab new-window && ret=0
else
compset -S ',*'
state=urls
fi
;;
addBookmark*) state=urls;;
openFile*) _files "$@" -W ~;;
saveAs*)
if compset -P "*,"; then
_wanted types expl 'data type' \
compadd "$@" -M 'm:{a-zA-Z}={A-Za-z}' HTML Text PostScript && ret=0
else
compset -S ",*" || suf=","
_files -qS "$suf" -W ~ && ret=0
fi
;;
mailto*)
_email_addresses -s, -c && ret=0
;;
*)
compset -S '(|\\)\(*' || suf="${${QIPREFIX:+(}:-\(}"
_wanted commands expl 'remote commands' \
compadd -qS "$suf" -M 'm:{a-zA-Z}={A-Za-z}' -a \
remote_commands && ret=0
;;
esac
fi
if [[ "$state" = "urls" ]]; then
# Complete mozilla urls
if compset -P about: ; then
_wanted values expl 'about what' \
compadd "$@" authors blank cache document fonts global hype image-cache \
license logo memory-cache mozilla plugins && ret=0
elif compset -P news: ; then
_newsgroups "$@" && ret=0
elif compset -P mailto: ; then
_email_addresses -c && ret=0
else
_tags prefixes
while _tags; do
while _next_label prefixes expl 'URL prefix' "$@"; do
_urls "$expl[@]" && ret=0
compset -S '[^:]*'
compadd -S '' "$expl[@]" about: news: mailto: mocha: javascript: && ret=0
done
(( ret )) || return 0
done
fi
fi
return ret
|
