blob: c5cd41bf6e08ca104c92fc913a61e49db28d5b24 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
|
#autoload
# Usage: _urls [-f]
# Options:
# -f : complete files.
#
# Configuration keys used:
#
# urls_path
# The path to a directory containing a URL database, such as:
#
# % cd ~/.zsh/urls
# % find . -ls
# ... drwxr-xr-x ... 512 Sep 3 02:46 .
# ... drwxr-xr-x ... 512 Sep 3 02:48 ./http
# ... drwxr-xr-x ... 512 Sep 3 02:52 ./http/www.zsh.org
# ... drwxr-xr-x ... 512 Sep 3 03:01 ./http/www.zsh.org/mla
# ... drwxr-xr-x ... 512 Sep 3 03:01 ./http/www.zsh.org/mla/workers
# ... drwxr-xr-x ... 512 Sep 3 03:01 ./http/www.zsh.org/mla/workers/1999
# ... -rw-r--r-- ... 0 Sep 3 03:01 ./http/www.zsh.org/mla/workers/1999/index.html
# ... drwxr-xr-x ... 512 Sep 3 02:48 ./http/sunsite.auc.dk
# ... drwxr-xr-x ... 512 Sep 3 02:48 ./http/sunsite.auc.dk/zsh
# ... drwxr-xr-x ... 512 Sep 3 02:47 ./bookmark
# ... drwxr-xr-x ... 512 Sep 3 02:48 ./bookmark/zsh
# ... -rw-r--r-- ... 27 Sep 3 02:47 ./bookmark/zsh/home
# ... -rw-r--r-- ... 20 Sep 3 02:48 ./bookmark/zsh/meta
# % cat bookmark/zsh/home
# http://sunsite.auc.dk/zsh/
# % cat bookmark/zsh/meta
# http://www.zsh.org/
#
# urls_localhttp
# Specify a local web server in the form:
# hostname:doc root:user area
# where hostname is the name of the web server, doc root is the path to
# the default web pages for the server and user area is the directory
# name used by a user placing web pages within their home area.
# e.g. compconf urls_localhttp=www:/usr/local/apache/htdocs:public_html
local ipre scheme host user dirs files ret=1 expl
if [[ "$1" = -f ]]; then
shift
_files "$@" && return
fi
if [[ -z "$compconfig[urls_path]" ]]; then
compconfig[urls_path]=${ZDOTDIR:-$HOME}/.zsh/urls
fi
ipre="$IPREFIX"
if [[ -prefix [-+.a-z0-9]#: ]]; then
scheme="${PREFIX%%:*}"
compset -P "[-+.a-z0-9]#:"
else
_description expl 'URL prefix'
[[ -d $compconfig[urls_path]/bookmark ]] &&
compadd "$@" "$expl[@]" -S '' bookmark: && ret=0
compadd "$@" "$expl[@]" -S '' file: ftp:// gopher:// http:// && ret=0
return $ret
fi
case "$scheme" in
http|ftp|gopher) compset -P // || { compadd "$@" -S '' //; return };;
file)
if ! compset -P //; then
if [ -prefix / ]; then
_files "$@"
return
elif [ ! "$PREFIX" ]; then
compadd -S '/' - "${PWD%/}"
return
fi
fi
;;
bookmark)
if [[ -f "$compconfig[urls_path]/$scheme/$PREFIX$SUFFIX" &&
-s "$compconfig[urls_path]/$scheme/$PREFIX$SUFFIX" ]]; then
compadd "$@" -QU -- \
"$ipre$(<"$compconfig[urls_path]/$scheme/$PREFIX$SUFFIX")"
else
compadd "$@" -Q -S '/' - \
$compconfig[urls_path]/$scheme/$PREFIX*$SUFFIX(/:t) && ret=0
compadd "$@" -QS '' - \
$compconfig[urls_path]/$scheme/$PREFIX*$SUFFIX(.:t) || return $ret
fi
return
;;
esac
if [[ -prefix */* ]]; then
# Complete part after hostname
host=${PREFIX%%/*}
compset -P "$host/"
if [[ "$compconfig[urls_localhttp]" = ${host}:* ]]; then
if [[ -prefix \~ ]]; then
compset -P \~
if [[ -prefix */* ]]; then
user=${PREFIX%%/*}
compset -P $user/
_path_files -W ~$user/${${(s.:.)compconfig[urls_localhttp]}[3]}/
else
_users -S/
fi
else
_path_files -W ${${(s.:.)compconfig[urls_localhttp]}[2]}
fi
else
_path_files -W $compconfig[urls_path]/$scheme/$host/
fi
else
# Complete hosts
dirs=($compconfig[urls_path]/$scheme/$PREFIX*$SUFFIX(/:t))
(( $#dirs )) || _hosts -S/ && ret=0
[ "$scheme" = "http" ] &&
dirs=($dirs ${${(s.:.)compconfig[urls_localhttp]}[1]})
compadd "$@" -Q -S '/' - $dirs || return $ret
fi
|