blob: 825786d808bd11a2ecc7b015758891793a81e2b3 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
#compdef rlogin rsh remsh rcp
_rlogin () {
local accounts_users_hosts
local varname="$words[1]_accounts"
if (( ${(P)+varname} )); then
accounts_users_hosts=( ${(P)varname} )
else
accounts_users_hosts=( $my_accounts )
fi
case "$words[1]" in
rlogin)
_arguments -s \
'-8[allow 8-Bit data]' \
'-e-[specify escape character]:escape character:' \
'-l[specify login user name]:login as:_rlogin_users' \
':remote host name:_rlogin_hosts'
;;
rsh|remsh)
local state line ret=1
typeset -A options
_arguments -s \
'-n[ignore stdin]' \
'-l[specify login user name]:login as:_rlogin_users' \
':remote host name:_rlogin_hosts' \
':command: _command_names -e' \
'*::command:->command' && ret=0
if [[ -n "$state" ]]; then
shift 1 words
(( CURRENT-- ))
_normal && ret=0
fi
return ret
;;
rcp)
local state line ret=1
typeset -A options
_arguments -s \
'-p[preserve modification times]' \
'-r[recursively copy directories]' \
'*:files:->files' && ret=0
if [[ -n "$state" ]]; then
if compset -P '*:'; then
_files && ret=0
elif compset -P '*@'; then
_rlogin_hosts -S: -q && ret=0
else
_files && ret=0
_rlogin_all_hosts -S: -q && ret=0
_rlogin_users -S@ -q && ret=0
fi
fi
return ret
;;
esac
}
_rlogin_users () {
_combination accounts_users_hosts users "$@"
}
_rlogin_hosts () {
if [[ "$IPREFIX" == *@ ]]; then
_combination accounts_users_hosts "users=${IPREFIX/@}" hosts "$@"
else
_combination accounts_users_hosts \
${options[-l]:+"users=${options[-l]:q}"} hosts "$@"
fi
}
_rlogin_all_hosts () {
_combination accounts_users_hosts hosts "$@"
}
_rlogin "$@"
|
