blob: d98fa433ac6e40b73475b29edd11fa3438754de6 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
#autoload
local expl ret=1 list disp
if (( $+commands[lsallq] )); then
# Use AIX's command to list print queues
_wanted printers expl printer compadd $(lsallq)
return
fi
if (( ! $+_lp_cache )); then
local file entry names i
file=( /etc/(printcap|printers.conf)(N) )
_lp_cache=()
_lp_alias_cache=()
if (( $#file )); then
while read entry; do
if [[ "$entry" = [^[:blank:]\#\*_]*:* ]]; then
names=( "${(s:|:)entry%%:*}" )
if [[ "$entry" = *:description=* ]]; then
disp="${${entry##*:description=}%%:*}"
elif [[ $#names -gt 1 && "$names[-1]" = *\ * ]] ;then
disp="$names[-1]"
else
disp=''
fi
if [[ -n "$disp" ]]; then
_lp_cache=( "$_lp_cache[@]" "${names[1]}:${disp}" )
_lp_alias_cache=( "$_lp_alias_cache[@]" "${(@)^names[2,-1]:#*\ *}:${disp}" )
else
_lp_cache=( "$_lp_cache[@]" "${names[1]}" )
_lp_alias_cache=( "$_lp_alias_cache[@]" "${(@)names[2,-1]:#*\ *}" )
fi
fi
done < $file[1]
fi
(( $#_lp_cache )) || _lp_cache=( 'lp0:Guessed default printer' )
(( $#_lp_alias_cache )) || unset _lp_alias_cache
fi
if zstyle -T ":completion:${curcontext}:printers" verbose; then
zformat -a list ' -- ' "$_lp_cache[@]"
disp=(-ld list)
else
disp=()
fi
_wanted printers expl printer \
compadd "$disp[@]" - "${(@)_lp_cache%%:*}" && return 0
(( $+_lp_alias_cache )) || return 1
if zstyle -T ":completion:${curcontext}:printers" verbose; then
zformat -a list ' -- ' "$_lp_alias_cache[@]"
disp=(-ld list)
else
disp=()
fi
_wanted printers expl printer \
compadd "$disp[@]" - "${(@)_lp_alias_cache%%:*}" && return 0
return 1
|
