blob: 8475d2056d8098bc5d150b6f824300a251c67843 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
#autoload
# Helper function for _path_files to handle the file-list style.
# arguments:
# name of parameter containing file matches
# directory prefix
# Sets array listfiles to the display strings and the array
# listopts appropriately to be added to the compadd command line.
local stat f elt what dir
local -a stylevals
integer ok
listfiles=()
listopts=()
zstyle -a ":completion:${curcontext}:" file-list stylevals || return 1
# TODO: more flexible way of handling the following? e.g. use $compstate?
case $WIDGETSTYLE in
(*complete*)
what=insert
;;
(*)
what=list
;;
esac
for elt in $stylevals; do
case $elt in
(*($what|all|true|1|yes)*=<->)
# use long format if no more than the given number of matches
(( ${(P)#1} <= ${elt##*=} )) && (( ok = 1 ))
break
;;
(*($what|all|true|1|yes)[^=]#)
# always use long format
(( ok = 1 ))
break
;;
esac
done
(( ok )) || return 1
zmodload -i zsh/stat 2>/dev/null || return 1
{
# Enable stat temporarily if disabled to avoid clashes.
integer disable_stat
if [[ ${builtins[stat]} != defined ]]; then
(( disable_stat = 1 ))
enable stat
fi
dir=${2:+$2/}
dir=${(Q)dir}
for f in ${(PQ)1}; do
if [[ ! -e "$dir$f" ]]; then
listfiles+=("$dir$f")
continue
fi
# Borrowed from Functions/Example/zls
stat -s -H stat -F "%b %e %H:%M" - "$dir$f" >/dev/null 2>&1
listfiles+=("$stat[mode] ${(l:3:)stat[nlink]} ${(r:8:)stat[uid]} \
${(r:8:)stat[gid]} ${(l:8:)stat[size]} $stat[mtime] $f")
done
(( ${#listfiles} )) && listopts=(-d listfiles -l -o)
} always {
(( disable_stat )) && disable stat
}
return 0
|