blob: 490d70bc83ee32d3e4961c2b32fe584b991a6c6a (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
#compdef iconv
local expl curcontext="$curcontext" state line codeset LOCPATH
if _pick_variant gnu=GNU unix --version; then
_arguments -C \
{'(--from-code --list)-f','(-f --list)--from-code='}'[specify code set of input file]:code set:->codeset' \
{'(--to-code --list)-t','(-t --list)--to-code='}'[specify code set for output]:code set:->codeset' \
'--list[list all character code sets]' \
'--verbose[print progress information]' \
{'(--help)-\?','(-\?)--help'}'[display help information]' \
'--usage[display a short usage message]' \
{'(--version)-V','(-V)--version'}'[print program version]' \
'1:file:_files' && return 0
if [[ $state = codeset ]]; then
_wanted codesets expl 'code set' \
compadd "$@" ${${(s:,:)$(iconv --list|sed -n '/^$/,$ p')}## #}
fi
else
_arguments -C \
'-f[specify code set of input file]:code set:->codeset' \
'-t[specify code set for output]:code set:->codeset' \
'1:file:_files' && return 0
if [[ $state = codeset ]]; then
if [[ -f /usr/lib/iconv/iconv_data ]]; then # IRIX & Solaris
codeset=( ${${(f)"$(</usr/lib/iconv/iconv_data)"}%%[[:blank:]]*} )
elif [[ -d ${LOCPATH:=/usr/lib/nls/loc}/iconv ]]; then # OSF
codeset=( $LOCPATH/iconv/*(N:t) )
codeset=( ${(j:_:s:_:)codeset} )
else
return 1
fi
_wanted codesets expl 'code set' compadd "$@" -a codeset
fi
fi
|
