blob: f8c535a449ec05e796e5631d26762afc3c703568 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
|
#compdef comm gcomm
local -a args aopts=( -A '-*' )
args=(
'-1[suppress lines unique to first file]'
'-2[suppress lines unique to second file]'
'-3[suppress lines that appear in both files]'
'1:file to compare:_files'
'2:file to compare:_files'
)
if _pick_variant gnu=GNU unix --version; then
aopts=( )
args+=(
'(--nocheck-order)--check-order[check input is correctly sorted]'
"(--check-order)--nocheck-order[don't check input is correctly sorted]"
'--output-delimiter=[specify column delimiter]:delimiter'
'--total[display summary]'
'(-z --zero-terminated)'{-z,--zero-terminated}'[use NUL as line delimiter]'
'(- : *)--version[display version information]'
'(- : *)--help[display help information]'
)
elif [[ $OSTYPE = (freebsd|dragonfly|darwin)* ]]; then
args+=( '-i[case insensitive comparison of lines]' )
elif [[ $OSTYPE = (openbsd|netbsd)* ]]; then
args+=( '-f[case insensitive comparison of lines]' )
fi
_arguments -s -S $aopts : $args
|
