blob: 347e25e2a98027cee8d644e32c4be1d16d7cef9d (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
#compdef svcadm
_svcadm() {
local context state line subcmds
typeset -A opt_args
subcmds=( enable disable restart refresh mark delegate clear milestone )
if [[ $service == "svcadm" ]]; then
_arguments -C -A "-*" \
'-v[Print actions verbosely]' \
'*::command:->subcmd' && return 0
if (( CURRENT == 1 )); then
_wanted commands expl 'svcadm subcommand' compadd -a subcmds
return
fi
service="$words[1]"
curcontext="${curcontext%:*}=$service:"
fi
case $service in
(enable)
_arguments -A "-*" \
'-r[Recursively enable dependencies]' \
'-s[Wait for service to come online]' \
'-T[Timeout for -s]:seconds:' \
'-t[State change is temporary]' \
'*:instance FMRI:_svcs_fmri -i'
;;
(disable)
_arguments -A "-*" \
'-s[Wait for service to become disabled]' \
'-T[Timeout for -s]:seconds:' \
'-t[State change is temporary]' \
'*:instance FMRI:_svcs_fmri -i'
;;
(mark)
_arguments -A "-*" \
'-I[Change state immediately]' \
"-s[Wait for service to reach the new state]" \
'-T[Timeout for -s]:seconds:' \
'-t[State change is temporary]' \
':state:(degraded maintenance)' \
':instance FMRI:_svcs_fmri -i'
;;
(restart|refresh|clear)
_arguments \
"-s[Wait for service to $service]" \
'-T[Timeout for -s]:seconds:' \
'*:instance FMRI:_svcs_fmri -i'
;;
(delegate)
_arguments -A "-*" \
'-s[Wait for instances to come online]' \
'-T[Timeout for -s]:seconds:' \
':restarter FMRI:_svcs_fmri -r' \
'*:FMRI:_svcs_fmri -i'
;;
(milestone)
_arguments -A "-*" \
'-d[Make milestone the default]' \
'-s[Wait for the transition to the new milestone]' \
'-T[Timeout for -s]:seconds:' \
'*:milestone FMRI:_svcs_fmri -m'
;;
(*)
_message "unknown svcadm subcommand: $service"
esac
}
_svcadm "$@"
|
