blob: 5f4802f91d61c4fa402ecf1194d4d58f45cff75b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
|
#compdef ldconfig ldconfig.real
local ret=1
local -a context line state state_descr
local -A opt_args
_arguments -s -S : \
'(x -v --verbose)'{-v,--verbose}'[output verbosely]' \
'(x)*: :->files' \
+ x \
'(: -)'{-\?,--help}'[display help information]' \
'(: -)'{-p,--print-cache}'[display libraries in current cache]' \
'(: -)--usage[display brief usage information]' \
'(: -)'{-V,--version}'[display version information]' \
+ l \
'(x o)-l[manually link individual libraries (library mode)]' \
+ o \
'(x l -c --format)'{-c+,--format=}'[specify cache format]:cache format:(old new compat)' \
'(x l)-C+[specify cache file to use instead of /etc/ld.so.cache]:cache file:_files' \
'(x l)-f+[specify configuration file to use instead of /etc/ld.so.conf]:configuration file:_files' \
'(x l -i --ignore-aux-cache)'{-i,--ignore-aux-cache}'[ignore auxiliary cache file]' \
'(x l -N)-n[process only directories specified on command line (implies -N)]' \
'(x l)-N[do not rebuild cache]' \
'(x l)-r+[specify root directory]:root directory:_directories' \
'(x l)-X[do not update symbolic links]' \
&& ret=0
[[ $state == files ]] &&
if [[ -n ${opt_args[(I)l--l]} ]]; then
_object_files && ret=0
else
_directories && ret=0
fi
return ret
|