about summary refs log tree commit diff
path: root/Completion/Debian/Command/_dscverify
blob: 4d383c6c4b84c3de44548ca5920d69700e84cbe4 (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
#compdef dscverify

# $ dscverify --version
# This is dscverify, from the Debian devscripts package, version 2.20.2
# ...

_dscverify() {
  local all_opts=(
    '--help[show the help message and exit]'
    '--version[show the version + copyright and exit]'
    '--no-default-keyrings[do not check against the default keyrings]'
    '*--keyring[add keyring to the list of keyrings used]:keyring:_files -g "*.(kbx|gpg)(-.)"'
    '(--nosigcheck --no-sig-check -u)'{--nosigcheck,--no-sig-check,-u}'[do not verify the GPG signature]'
    '--verbose[do not suppress GPG output]'
    '*:dsc file:_files -g "*.(changes|dsc|buildinfo)(-.)"'
  )

  local first_only=(
    '(--no-conf --noconf)'{--no-conf,--noconf}'[do not read the devscripts config file]'
  )

  if (( CURRENT == 2 )); then
    all_opts+=($first_only)
  fi

  _arguments \
    "$all_opts[@]"
}

_dscverify "$@"