blob: 1884717e2f3ac1a40daa5111a8206865ab2b5721 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
#autoload
if (( $# )); then
# We have arguments: the tags supported in this context.
local curcontext="$curcontext" order tag nodef
if [[ "$1" = -C?* ]]; then
curcontext="${curcontext%:*}:${1[3,-1]}"
shift
elif [[ "$1" = -C ]]; then
curcontext="${curcontext%:*}:${2}"
shift 2
else
targs=()
fi
[[ "$1" = -(|-) ]] && shift
if zstyle -a ":completion:${curcontext}:" group-order order; then
local name
for name in "$order[@]"; do
compadd -J "$name"
compadd -V "$name"
compadd -J "$name" -1
compadd -V "$name" -1
compadd -J "$name" -2
compadd -V "$name" -2
done
fi
# Set and remember offered tags.
comptags -i "$curcontext" "$@"
# Sort the tags.
if [[ -n "$_sort_tags" ]]; then
"$_sort_tags" "$@"
elif zstyle -a ":completion:${curcontext}:" tag-order order; then
for tag in $order; do
case $tag in
-) nodef=yes;;
*\(\)) "${${tag%%[ ]#\(\)}##[ ]#}" "$@";;
\!*) comptry "${(@)argv:#(${(j:|:)~${=tag[2,-1]}})}";;
?*) comptry ${=tag};;
esac
done
[[ -z "$nodef" ]] && comptry "$@"
else
# The first ones give the default behaviour.
comptry arguments values
comptry options
comptry globbed-files
comptry directories
comptry all-files
comptry "$@"
fi
# Return non-zero if at least one set of tags should be used.
comptags -T
return
fi
# The other mode: switch to the next set of tags.
comptags -N
|