about summary refs log tree commit diff
path: root/Completion/Core/_alternative
blob: 158f3a07ad2a0d61d35c427f33c3f4bb9e39087b (plain) (blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
#autoload

local tags def expl descr action mesgs nm="$compstack[nmatches]"
local context

if [[ "$1" = -C?* ]]; then
  context="${1[3,-1]}"
  shift
elif [[ "$1" = -C ]]; then
  context="$2"
  shift 2
fi

mesgs=()

_tags -C "$context" "${(@)argv%%:*}"

while _tags; do
  for def; do
    if _requested "${def%%:*}"; then
      descr="${${def#*:}%%:*}"
      action="${def#*:*:}"

      _description expl "$descr"

      if [[ "$action" = \ # ]]; then

        # An empty action means that we should just display a message.

        mesgs=( "$mesgs[@]" "$descr")
      elif [[ "$action" = \(\(*\)\) ]]; then
        local ws

        # ((...)) contains literal strings with descriptions.

        eval ws\=\( "${action[3,-3]}" \)

        _describe "$descr" ws -M 'r:|[_-]=* r:|=*'
      elif [[ "$action" = \(*\) ]]; then

        # Anything inside `(...)' is added directly.

        compadd "$expl[@]" - ${=action[2,-2]}
      elif [[ "$action" = \{*\} ]]; then

        # A string in braces is evaluated.

        eval "$action[2,-2]"
      elif [[ "$action" = \ * ]]; then

        # If the action starts with a space, we just call it.

        ${(e)=~action}
      else

        # Otherwise we call it with the description-arguments built above.

        action=( $=action )
        ${(e)action[1]} "$expl[@]" ${(e)~action[2,-1]}
      fi
    fi
  done
  [[ nm -ne compstate[nmatches] ]] && return 0
done

for descr in "$mesgs[@]"; do
  _message "$descr"
done

return 1