blob: 5b18ec228c95d89adc25f6b86b72c27f766c54f2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
|
#compdef popd
# This just completes the numbers after +, showing the full directory list
# with numbers. For - we do the same thing, but reverse the numbering (other
# way round if pushdminus is set). Note that this function is also called
# from _cd for cd and pushd.
setopt localoptions nonomatch
[[ $PREFIX = [-+]* ]] || return 1
local expl list lines revlines ret=1 i
IPREFIX=$PREFIX[1]
PREFIX=$PREFIX[2,-1]
# get the list of directories with their canonical number
# and turn the lines into an array, removing the current directory
lines=( "$dirstack[@]" )
if [[ ( $IPREFIX = - && ! -o pushdminus ) ||
( $IPREFIX = + && -o pushdminus ) ]]; then
integer i
revlines=( $lines )
for (( i = 1; i <= $#lines; i++ )); do
lines[$i]="$((i-1)) -- ${revlines[-$i]}"
done
else
for (( i = 1; i <= $#lines; i++ )); do
lines[$i]="$i -- ${lines[$i]}"
done
fi
# get the array of numbers only
list=(${lines%% *})
_description expl 'directory stack index'
compadd "$expl[@]" -ld lines -V dirs -Q - "$list[@]" && ret=0
[[ -z $compstate[list] ]] && compstate[list]=list && ret=0
[[ -n $compstate[insert] ]] && compstate[insert]=menu && ret=0
return ret
|
