blob: 5aeeadf1006015abd913887a9aaa42cdd03b8fc3 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
#autoload
# This can be used to add options or values with descriptions as matches.
local _opt _expl _tmps _tmpd _tmpmd _tmpms _ret=1 _showd _nm _hide _args
local _type=values _descr
# Get the option.
if [[ "$1" = -o ]]; then
_type=options
shift
elif [[ "$1" = -t ]]; then
_type="$2"
shift 2
elif [[ "$1" = -t* ]]; then
_type="${1[3,-1]}"
shift
fi
# Do the tests. `showd' is set if the descriptions should be shown.
zstyle -T ":completion:${curcontext}:$_type" verbose && _showd=yes
_descr="$1"
shift
[[ "$_type" = options ]] &&
zstyle -t ":completion:${curcontext}:options" prefix-hidden && _hide=yes
_tags "$_type"
while _tags; do
while _next_label "$_type" _expl "$_descr"; do
if [[ -n "$_showd" ]]; then
compdescribe -I ' -- ' "$@"
else
compdescribe -i "$@"
fi
while compdescribe -g _args _tmpd _tmpmd _tmps _tmpms; do
# See if we should remove the option prefix characters.
if [[ -n "$_hide" ]]; then
if [[ "$PREFIX" = --* ]]; then
_tmpd=( "${(@)_tmpd#--}" )
_tmps=( "${(@)_tmps#--}" )
elif [[ "$PREFIX" = [-+]* ]]; then
_tmpd=( "${(@)_tmpd#[-+]}" )
_tmps=( "${(@)_tmps#[-+]}" )
fi
fi
compadd "$_args[@]" "$_expl[@]" -ld _tmpd - "$_tmpmd[@]" && _ret=0
compadd "$_args[@]" "$_expl[@]" -d _tmps - "$_tmpms[@]" && _ret=0
done
done
(( _ret )) || return 0
done
return 1
|
