blob: 202a46c4abff5ff89ea3c6f57a56c5a07e035858 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
|
#autoload
# Provides completion for file flags (formerly part of _chflags)
local curcontext=$curcontext su=$(( ! EUID || $+_comp_priv_prefix ))
local -a context line state state_descr copts=( "${@}" ) flags flag_descs
local -A val_args
flag_descs+=(
nodump nodump
uappnd 'user append-only'
uchg 'user immutable'
)
if (( su )); then
flag_descs+=(
arch archived
sappnd 'system append-only'
schg 'system immutable'
)
fi
if [[ $OSTYPE = (darwin|dragonfly|freebsd|netbsd)* ]]; then
flag_descs+=(opaque opaque)
if [[ $OSTYPE = darwin* ]]; then
flag_descs+=(hidden hidden)
fi
if [[ $OSTYPE = (dragonfly|freebsd)* ]]; then
flag_descs+=(uunlnk 'user undeletable')
(( su )) &&
flag_descs+=(sunlnk 'system undeletable')
fi
if [[ $OSTYPE = dragonfly* ]]; then
flag_descs+=(
cache cache
nouhistory 'user nohistory'
)
(( su )) && flag_descs+=(
noscache noscache
noshistory 'system nohistory'
)
fi
[[ $OSTYPE = freebsd* ]] && flag_descs+=(
uarch archive
uhidden hidden
uoffline offline
urdonly 'DOS, Windows and CIFS readonly'
ureparse 'Windows reparse point'
usparse 'sparse file'
usystem 'DOS, Windows and CIFS system'
)
fi
for 1 2 in $flag_descs; do
if [[ $1 = no* ]]; then
flags+=("(${1#no})$1[set the $2 flag]"
"($1)${1#no}[unset the $2 flag]")
else
flags+=("(no$1)$1[set the $2 flag]"
"($1)no$1[unset the $2 flag]")
fi
done
_values -O copts -s , 'file flags' $flags
|