blob: 4e66c2383a61eba85dfc2ee2e798df4750f68345 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
|
#compdef vmctl
local context line state state_descr
local -a subcommands vmctl_status
local -A opt_args
_vm_name() {
compadd "$@" - ${${${(@f)"$(_call_program vmctl_status vmctl status)"}[2,-1]}##* }
}
_vm_switch() {
[[ -r /etc/vm.conf ]] &&
compadd "$@" - ${${${(M)${(f)"$(</etc/vm.conf)"}:#switch *}##switch ##\"#}%%\"# *}
}
subcommands=(
console:'connect to the console of the VM'
create:'create a VM disk image'
load:'load additional configuration'
log:'change logging verbosity'
pause:'pause a VM'
receive:'receive a VM from stdin'
reload:'remove stopped VMs and reload config'
reset:'reset specified component'
send:'send VM to stdout and terminate it'
{show,status}:'list VMs running or just the specified id'
start:'start a VM'
stop:'stop a VM'
unpause:'unpause a VM'
)
if (( CURRENT == 2 )); then
_describe subcommand subcommands
else
shift words; (( CURRENT-- ))
case $words[1] in
console|pause|send|show|status|stop|unpause)
_arguments ':id:_vm_name'
;;
create)
_arguments \
':path:_files' \
': :(-s)' \
':disk size in megabytes: '
;;
load)
_arguments ':configuration file:_files'
;;
log)
_arguments ':logging verbosity:(brief verbose)'
;;
receive)
_arguments ':name: '
;;
reset)
_arguments ':reset option:((
all\:"reset the running state"
switches\:"reset the configured switches"
vms\:"reset and terminate all VMs"
))'
;;
start)
if (( CURRENT == 2 )); then
_vm_name
else
shift words; (( CURRENT-- ))
_arguments -s \
'-b+[boot with the specified kernel or BIOS image]:boot image:_files' \
'-c[automatically connect to the VM console]' \
'*-d+[disk image file]:disk image:_files' \
'-i+[number of network interfaces]:number: ' \
'-L[add a local network interface]' \
'-m+[memory size in megabytes]:megabytes: ' \
'-n+[specify switch to attach]:switch:_vm_switch' \
'-r+[ISO image file for virtual CD-ROM]:ISO image:_files'
fi
;;
esac
fi
|
