#compdef add-zle-hook-widget

_add-zle-hook-widget_types() {
  local -a tmp

  autoload -U add-zle-hook-widget
  add-zle-hook-widget -h > /dev/null # sets the zstyle
  zstyle -g tmp zle-hook types

  compadd "$@" -M 'L:|=zle-' -M 'r:|-=* r:|=*' -- zle-${^tmp}
}

_add-zle-hook-widget_widgets() {
  if (( $+opt_args[-d] )); then
    local -a tmp
    zstyle -g tmp $line[1] widgets
    _wanted widgets expl "installed hook" compadd -- ${tmp#<->:} && return 0
  else
    local -a user_widgets=( ${(k)widgets[(R)user:*]} )
    _wanted widgets expl widget compadd -M 'r:|-=* r:|=*' -a user_widgets && return 0
  fi
  return 1
}

_add-zle-hook-widget() {
  local context state state_descr line
  typeset -A opt_args
  _arguments -s -w -S : \
    '(-D)-d[remove HOOK from the array]' \
    '(-d)-D[interpret HOOK as pattern to remove from the array]' \
    {-U,-z,-k}"[passed to 'autoload']" \
    ':hook type:_add-zle-hook-widget_types' \
    ':widget:_add-zle-hook-widget_widgets'
}

_add-zle-hook-widget "$@"