#compdef acroread

local curcontext="$curcontext" state line

_x_arguments -C \
  -help \
  -helpall \
  \*-iconic \
  \*+iconic \
  '-name:application name:_x_name' \
  '*-setenv:<var>=<value>' \
  -tempFile \
  '-tempFileTitle:title' \
  '(+useFrontEndProgram)-useFrontEndProgram' \
  '(-useFrontEndProgram)+useFrontEndProgram' \
  '-visual:X visual:_x_visual' \
  '-xrm:X resource specification:_x_resource' \
  '-toPostScript:*::PostScript conversion options:= ->tops' \
  '*:pdf file:_files -g "*.(#i)pdf"' && return

[[ -n "$state" ]] && _arguments \
  '-pairs:*:pdf_file_1 ps_file_1 ...:_files -g "*.(#i)(pdf|ps)"' \
  -binary \
  '-start:integer' \
  '-end:integer' \
  -optimizeForSpeed \
  -landscape \
  -reverse \
  '(-even)-odd' \
  '(-odd)-even' \
  -commentsOff \
  '(-level2 -level3)-level1' \
  '(-level1 -level3)-level2' \
  '(-level1 -level2)-level3' \
  -printerhalftones \
  -saveVM \
  '-scale:integer' \
  -shrink \
  '-size:page size (or custom size wxh in points):(letter tabloid ledger legal executive a3 a4 a5 b4 b5)' \
  '-transQuality:transparency flattening level:(1 2 3 4 5)' \
  '*:pdf file:_files -g "*.(#i)pdf"' && return

return 1