From 23f2b4503c9d7697e382fed550d3bf846b81dd5c Mon Sep 17 00:00:00 2001
From: Peter Stephenson <pws@users.sourceforge.net>
Date: Fri, 19 Sep 2008 12:58:46 +0000
Subject: users/13252 and elsewhere: Frank Terbeck plus tweaks: add VCS_Info
 function system

---
 Functions/VCS_Info/vcs_info_printsys | 37 ++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 Functions/VCS_Info/vcs_info_printsys

(limited to 'Functions/VCS_Info/vcs_info_printsys')

diff --git a/Functions/VCS_Info/vcs_info_printsys b/Functions/VCS_Info/vcs_info_printsys
new file mode 100644
index 000000000..d84682296
--- /dev/null
+++ b/Functions/VCS_Info/vcs_info_printsys
@@ -0,0 +1,37 @@
+## vim:ft=zsh
+## Written by Frank Terbeck <ft@bewatermyfriend.org>
+## Distributed under the same BSD-ish license as zsh itself.
+
+setopt localoptions noksharrays extendedglob NO_shwordsplit
+local sys
+local -a disabled enabled
+
+zstyle -a ":vcs_info:-init-:${1:-default}:-all-" "enable" enabled
+(( ${#enabled} == 0 )) && enabled=( all )
+
+if [[ -n ${(M)enabled:#(#i)all} ]] ; then
+    enabled=( ${VCS_INFO_backends} )
+    zstyle -a ":vcs_info:-init-:${1:-default}:-all-" "disable" disabled
+else
+    for sys in ${VCS_INFO_backends} ; do
+        [[ -z ${(M)enabled:#$sys} ]] && disabled+=( ${sys} )
+    done
+    enabled=( ${VCS_INFO_backends} )
+fi
+
+print -l '## list of supported version control backends:' \
+         '## disabled systems are prefixed by a hash sign (#)'
+
+for sys in ${VCS_INFO_backends} ; do
+    [[ -n ${(M)disabled:#${sys}} ]] && printf '#'
+    printf '%s\n' ${sys}
+done
+
+print -l '## flavours (cannot be used in the enable or disable styles; they' \
+         '## are enabled and disabled with their master [git-svn -> git])'   \
+         '## they *can* be used contexts: '\'':vcs_info:git-svn:*'\''.'
+
+for sys in ${VCS_INFO_backends} ; do
+    VCS_INFO_detect_${sys} --flavours
+done
+return 0
-- 
cgit 1.4.1