From d3fdf5d8515c0e21d385581a6d063821a4a55e55 Mon Sep 17 00:00:00 2001
From: Oliver Kiddle <opk@users.sourceforge.net>
Date: Thu, 26 Sep 2002 12:11:05 +0000
Subject: merge changes from 4.1 branch

---
 Completion/Unix/Command/_killall |  9 +++++++++
 Completion/Unix/Command/_mail    | 24 ++++++++++++++++++++++++
 2 files changed, 33 insertions(+)
 create mode 100644 Completion/Unix/Command/_killall
 create mode 100644 Completion/Unix/Command/_mail

(limited to 'Completion')

diff --git a/Completion/Unix/Command/_killall b/Completion/Unix/Command/_killall
new file mode 100644
index 000000000..6ec022227
--- /dev/null
+++ b/Completion/Unix/Command/_killall
@@ -0,0 +1,9 @@
+#compdef killall killall5
+
+if [[ $service = killall && "$OSTYPE" = linux* ]]; then
+  _alternative \
+      'signals:: _signals -p' \
+      'processes:process:{ compadd "$expl[@]" ${${${${(f)"$(_call_program processes-names ps ${${EUID/(#s)0(#e)/xa}//[0-9]#/} ho cmd 2> /dev/null)"//[][\(\)]/}:#(ps|COMMAND|-*)}%%\ *}:t} }'
+else
+  _signals -p
+fi
diff --git a/Completion/Unix/Command/_mail b/Completion/Unix/Command/_mail
new file mode 100644
index 000000000..82a3a59d0
--- /dev/null
+++ b/Completion/Unix/Command/_mail
@@ -0,0 +1,24 @@
+#compdef mail mailx Mail mush zmail nail
+
+local curcontext="$curcontext" state line expl suf
+
+_arguments -C -s \
+  '(-f -u)*-b[specify a BCC recipient]:BCC recipient:->userhost' \
+  '(-f -u)*-c[specify a CC recipient]:CC recipient:->userhost' \
+  '(-b -c -u -s *)-f+[specify mail folder]:mailbox:_mailboxes' \
+  '(-f -u)-s+[specify a subject]:subject:' \
+  "(-b -c -f -s *)-u+[read specified user's mail]:user:_users" \
+  '(-f -u)*:recipient:->userhost' && return 0
+
+if [[ "$state" = userhost ]]; then
+  if compset -P '*@'; then
+    _description hosts expl 'remote host name'
+    _hosts "$expl[@]" && return 0
+  else
+    compset -S '@*' || suf='@'
+    _description users expl 'login name'
+    _users "$expl[@]" -q -S "$suf" && return 0
+  fi
+fi
+
+return 1
-- 
cgit 1.4.1