From 19010fafd9600fda83f7dae0bbc7fbc945204bf0 Mon Sep 17 00:00:00 2001
From: Daniel Shahaf <d.s@daniel.shahaf.name>
Date: Wed, 4 Mar 2015 22:32:12 +0000
Subject: New completion for add-zsh-hook

---
 Completion/Zsh/Function/_add-zsh-hook | 24 ++++++++++++++++++++++++
 1 file changed, 24 insertions(+)
 create mode 100644 Completion/Zsh/Function/_add-zsh-hook

(limited to 'Completion')

diff --git a/Completion/Zsh/Function/_add-zsh-hook b/Completion/Zsh/Function/_add-zsh-hook
new file mode 100644
index 000000000..c70a4976f
--- /dev/null
+++ b/Completion/Zsh/Function/_add-zsh-hook
@@ -0,0 +1,24 @@
+#compdef add-zsh-hook
+
+local context state state_descr line
+typeset -A opt_args
+
+_add-zsh-hook_hooks() {
+  if (( $+opt_args[-d] )); then
+    _wanted functions expl "installed hooks" compadd -a - "$line[1]_functions" && return 0
+  else
+    _functions && return 0
+  fi
+  return 1
+}
+
+_add-zsh-hook() {
+  _arguments -s -w -S : \
+    '(-D)-d[remove HOOK from the array]' \
+    '(-d)-D[interpret HOOK as pattern to remove from the array]' \
+    {-U,-z,-k}"[passed to 'autoload']" \
+    ':hook class:(chpwd precmd preexec periodic zshaddhistory zshexit zsh_directory_name)' \
+    ':hook function:_add-zsh-hook_hooks'
+}
+
+_add-zsh-hook "$@"
-- 
cgit 1.4.1