From a0ad55d34f94402f08582e303d043bf5400198b7 Mon Sep 17 00:00:00 2001
From: Sven Wischnowsky <wischnow@users.sourceforge.net>
Date: Mon, 2 Apr 2001 11:23:29 +0000
Subject: moved from Completion/Base/_in_vared

---
 Completion/Zsh/Context/_in_vared | 35 +++++++++++++++++++++++++++++++++++
 1 file changed, 35 insertions(+)
 create mode 100644 Completion/Zsh/Context/_in_vared

(limited to 'Completion/Zsh/Context')

diff --git a/Completion/Zsh/Context/_in_vared b/Completion/Zsh/Context/_in_vared
new file mode 100644
index 000000000..abd24dd95
--- /dev/null
+++ b/Completion/Zsh/Context/_in_vared
@@ -0,0 +1,35 @@
+#compdef -vared-
+
+local also
+
+# Completion inside vared.
+
+if [[ $compstate[vared] = *\[* ]]; then
+  if [[ $compstate[vared] = *\]* ]]; then
+    # vared on an array-element
+    compstate[parameter]=${${compstate[vared]%%\]*}//\[/-}
+    compstate[context]=value
+    also=-value-
+  else
+    # vared on an array-value
+    compstate[parameter]=${compstate[vared]%%\[*}
+    compstate[context]=value
+    also=-value-
+  fi
+else
+  # vared on a parameter, let's see if it is an array
+  compstate[parameter]=$compstate[vared]
+  if [[ ${(tP)compstate[vared]} = *(array|assoc)* ]]; then
+    compstate[context]=array_value
+    also=-array-value-
+  else
+    compstate[context]=value
+    also=-value-
+  fi
+fi
+
+# Don't insert TAB in first column. Never.
+
+compstate[insert]="${compstate[insert]//tab /}"
+
+_contexts "$also"
-- 
cgit 1.4.1