From e34a565a4a46908cccf09215ce9312b48629c514 Mon Sep 17 00:00:00 2001
From: Sven Wischnowsky <wischnow@users.sourceforge.net>
Date: Mon, 2 Apr 2001 12:15:23 +0000
Subject: moved to Completion/X/Command/_xmodmap

---
 Completion/X/_xmodmap | 96 ---------------------------------------------------
 1 file changed, 96 deletions(-)
 delete mode 100644 Completion/X/_xmodmap

(limited to 'Completion/X')

diff --git a/Completion/X/_xmodmap b/Completion/X/_xmodmap
deleted file mode 100644
index 5c7fcf3fe..000000000
--- a/Completion/X/_xmodmap
+++ /dev/null
@@ -1,96 +0,0 @@
-#compdef xmodmap
-
-local curcontext="$curcontext" state line ret=1
-typeset -A opt_args
-
-_x_arguments -C \
-  -{help,grammar,verbose,quiet} \
-  '-n[only show what would be done]' \
-  '*-e[specify expression]:expression:->expr' \
-  '-pm[print modifier map]' \
-  '-pk[print keymap table]' \
-  '-pke[print keymap table as expressions]' \
-  '-pp[print pointer map]' \
-  ':X mapping file:_files' && ret=0
-
-if [[ -n "$state" ]]; then
-  local expl expr="${PREFIX##[ 	]#}" what suf
-
-  if compset -P '[^ 	]##[ 	]##'; then
-    case "$expr" in
-    keycode*)
-      if compset -P '*=[ 	]#'; then
-        compset -P '*[ 	]'
-        what=ksyms
-      elif [[ "$expr" = *[\ \	]##[^\ \	]##[\ \	] ]]; then
-        IPREFIX="${IPREFIX}${PREFIX}"
-	PREFIX=''
-	compadd -S ' ' '=' && ret=0
-      else
-        _message 'key code or `any'"'"
-      fi
-      ;;
-    keysym*)
-      if compset -P '*=[ 	]#'; then
-        compset -P '*[ 	]'
-        what=ksyms
-      elif [[ "$expr" = *[\ \	]##[^\ \	]##[\ \	] ]]; then
-        IPREFIX="${IPREFIX}${PREFIX}"
-	PREFIX=''
-	compadd -S ' ' '=' && ret=0
-      else
-        what=ksym-eq
-      fi
-      ;;
-    clear*)
-      what=mods
-      ;;
-    (add|remove)*)
-      if compset -P '*[ 	]##'; then
-        what=ksyms
-      else
-        what=mods-eq
-      fi
-      ;;
-    pointer*)
-      if compset -P '*=[ 	]#'; then
-        compset -P '*[ 	]'
-        _description values expl 'button code'
-        compadd "$expl[@]" -qS ' ' 1 2 3 4 5 default
-        return
-      else
-        IPREFIX="${IPREFIX}${PREFIX}"
-	PREFIX=''
-	compadd -S ' ' '=' && ret=0
-      fi
-      ;;
-    esac
-
-    if [[ "$what" = *eq* ]]; then
-      suf=(-S ' = ')
-    elif [[ "$what" = *ksyms* ]]; then
-      if [[ -n "$compstate[quote]" ]]; then
-        suf=(-S "$compstate[quote] " -r "$compstate[quote] ")
-      else
-        suf=(-qS ' ')
-      fi
-    else
-      suf=()
-    fi
-
-    [[ "$what" = *mods* ]] && _x_modifier "$suf[@]" && ret=0
-    [[ "$what" = *ksym* ]] && _x_keysym "$suf[@]" && ret=0
-
-  else
-    _tags commands
-    while _tags; do
-      while _next_label commands expl command; do
-        compadd "$expl[@]" -S ' ' keycode keysym clear add remove && ret=0
-        compadd "$expl[@]" -S ' = ' pointer && ret=0
-      done
-      (( ret )) || return 0
-    done
-  fi
-fi
-
-return ret
-- 
cgit 1.4.1