From 97c08895aadc54af80395e4c24517a8bc3fd51bc Mon Sep 17 00:00:00 2001
From: Bart Schaefer <barts@users.sourceforge.net>
Date: Wed, 9 Feb 2005 16:28:39 +0000
Subject: Kris Shannon: 20901: fix missing $ in expression that parses script

---
 Completion/Unix/Command/_init_d | 28 ++++++++++++++++++++++++++++
 1 file changed, 28 insertions(+)
 create mode 100644 Completion/Unix/Command/_init_d

(limited to 'Completion/Unix')

diff --git a/Completion/Unix/Command/_init_d b/Completion/Unix/Command/_init_d
new file mode 100644
index 000000000..f439e8007
--- /dev/null
+++ b/Completion/Unix/Command/_init_d
@@ -0,0 +1,28 @@
+#compdef -p */(init|rc[0-9S]#).d/*
+
+local magic cmds what script
+
+_compskip=all
+
+# This should probably be system specific...
+
+script=$words[1]
+[[ $script = */* ]] || script=/etc/init.d/$script
+
+# If the file starts with `#!' we hope that this is a shell script
+# and get lines looking like <space>foo|bar) with the words in $what.
+
+what='(st(art|op|atus)|(force-|)re(start|load)|debug_(up|down)|dump(|_stats)|add|delete|clean|list)'
+
+read -u0 -k2 magic < $script && [[ $magic = '#!' ]] &&
+    cmds=( ${${(j:|:s:|:)${(M)${(f)"$(< $script)"}:#[[:blank:]]#(\'|)${~what}(\|${~what})#(\'|)\)}}//[^a-z_]} )
+
+# This would be the pattern to use every line of the form <space>foo).
+# Some people say this might match too many lines...
+#
+#    cmds=( ${${(j:|:s:|:)${(M)${(f)"$(< $script)"}:#[[:blank:]]#(\'|)[a-z_|]##\'|)\)}}//[^a-z_]} )
+
+(( $#cmds )) || zstyle -a ":completion:${curcontext}:commands" commands cmds ||
+    cmds=(start stop)
+
+_sub_commands $cmds
-- 
cgit 1.4.1