From 627c91357c29e6fbe8b32d1b5f17f02d555d8360 Mon Sep 17 00:00:00 2001
From: dana <dana@dana.is>
Date: Fri, 20 Jul 2018 11:15:32 -0500
Subject: 43196: Add completion for nginx

---
 Completion/Unix/Command/_nginx | 20 ++++++++++++++++++++
 1 file changed, 20 insertions(+)
 create mode 100644 Completion/Unix/Command/_nginx

(limited to 'Completion/Unix/Command/_nginx')

diff --git a/Completion/Unix/Command/_nginx b/Completion/Unix/Command/_nginx
new file mode 100644
index 000000000..7d785c822
--- /dev/null
+++ b/Completion/Unix/Command/_nginx
@@ -0,0 +1,20 @@
+#compdef nginx
+
+local -ah signals=(
+  'quit\:shut down gracefully (SIGQUIT)'
+  'reload\:reload configuration (SIGHUP)'
+  'reopen\:re-open log files (SIGUSR1)'
+  'stop\:shut down quickly (SIGTERM)'
+)
+
+_arguments -s -S : \
+  '(: * -)'{-\?,-h}'[display help information]' \
+  '(: * -)-v[display version information]' \
+  '(: * -)-V[display version information and configure options]' \
+  '-c+[specify configuration file]:configuration file:_files' \
+  '-g+[specify global configuration directives]:configuration directives' \
+  '-p+[specify prefix path]:prefix path:_directories' \
+  '(-s)-q[suppress non-error messages (with -t/-T)]' \
+  "(-q -t -T)-s+[send specified signal to master process]:signal:((${(j< >)${(@q-)signals}}))" \
+  '(-s -T)-t[test configuration]' \
+  '(-s -t)-T[test and dump configuration]'
-- 
cgit 1.4.1