From 43247252ddeedcf3955b030f2c77064089581cb0 Mon Sep 17 00:00:00 2001
From: dana <dana@dana.is>
Date: Mon, 17 Dec 2018 14:49:33 -0600
Subject: 43897: Add/update various completion functions

* Update tail to support -q/-v on NetBSD
* Add several new functions (with one change needed to _hosts compdefs)
---
 Completion/Unix/Command/_mkfifo | 20 ++++++++++++++++++++
 1 file changed, 20 insertions(+)
 create mode 100644 Completion/Unix/Command/_mkfifo

(limited to 'Completion/Unix/Command/_mkfifo')

diff --git a/Completion/Unix/Command/_mkfifo b/Completion/Unix/Command/_mkfifo
new file mode 100644
index 000000000..4f1d8c87e
--- /dev/null
+++ b/Completion/Unix/Command/_mkfifo
@@ -0,0 +1,20 @@
+#compdef mkfifo gmkfifo
+
+local -a aopts args
+
+if _pick_variant gnu='Free Soft' unix --version; then
+  args=(
+    '(: * -)--help[display help information]'
+    '(: * -)--version[display version information]'
+    '(-m --mode)'{-m+,--mode=}'[specify file mode]: :_file_modes'
+  )
+  [[ $OSTYPE == linux* ]] && args+=(
+    '(--context)-Z[set SELinux security context to default]'
+    '(-Z)--context=-[like -Z, or specify SELinux security context]:SELinux security context'
+  )
+else
+  aopts=( -A '-*' )
+  args=( '-m+[specify file mode]: :_file_modes' )
+fi
+
+_arguments -s -S $aopts : '*:FIFO:_files' $args
-- 
cgit 1.4.1