From 0de287ce9416cb5c2be8090bae3b7c89b2cd8b2a Mon Sep 17 00:00:00 2001
From: Sven Wischnowsky <wischnow@users.sourceforge.net>
Date: Wed, 18 Jul 2001 07:08:36 +0000
Subject: add support for -R option (15402)

---
 Completion/Unix/Command/_chown | 33 +++++++++++++++++++++++++++++++++
 1 file changed, 33 insertions(+)
 create mode 100644 Completion/Unix/Command/_chown

(limited to 'Completion/Unix/Command/_chown')

diff --git a/Completion/Unix/Command/_chown b/Completion/Unix/Command/_chown
new file mode 100644
index 000000000..34b31f6c9
--- /dev/null
+++ b/Completion/Unix/Command/_chown
@@ -0,0 +1,33 @@
+#compdef chown chgrp
+
+local suf usr grp req expl
+
+if [[ CURRENT -eq 2 || CURRENT -eq 3 && $words[CURRENT-1] = -* ]]; then
+  if [[ $service = chgrp ]] || compset -P '*[:.]'; then
+    if (( EGID && $+commands[groups] )); then  # except for root
+      _wanted groups expl 'group' compadd $(groups) && return 0
+    fi
+    _groups && return 0
+  else
+    if [[ $OSTYPE = (solaris*|hpux*|*bsd*) ]]; then
+      suf=':'
+    else
+      suf='.'
+    fi
+    compset -S '.*' && unset suf
+    _users -S "$suf" -q && return 0
+  fi
+else
+  if [[ $service = chgrp ]]; then
+    grp=${words[CURRENT-1]}
+  else
+    usr=${words[CURRENT-1]%%[.:]*}
+    usr=${${(M)usr:#[0-9]#}:-${userdirs[$usr]:+.$usr.}}
+    grp=${${(M)words[CURRENT-1]%%[.:]*}#?}
+  fi
+  [[ -n $grp ]] && grp="${${(M)grp:#[0-9]#}:-.$grp.}"
+  req=( ${usr:+\^u$usr} ${grp:+\^g$grp} )
+  (( EUID )) && req=( u$EUID$^req )
+
+  _files -g "*(${(j:,:)req})" && return 0
+fi
-- 
cgit 1.4.1